# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-www/gnash/gnash-9999.ebuild,v 1.1 2007/06/20 02:01:21 hanno Exp $

WANT_AUTOCONF="latest"
WANT_AUTOMAKE="latest"

inherit nsplugins autotools cvs kde-functions qt3 multilib
set-kdedir

DESCRIPTION="Gnash is a GNU Flash movie player that supports many SWF v7 features"
HOMEPAGE="http://www.gnu.org/software/gnash"
ECVS_SERVER="cvs.sv.gnu.org:/sources/${PN}"
ECVS_MODULE="${PN}"
S="${WORKDIR}/${PN}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="agg cairo cygnal debug ffmpeg gnome gstreamer gtk kde konqueror nsplugin opengl parallel video_cards_i810"

RDEPEND="
	dev-libs/boost
	dev-libs/libxml2
	media-libs/jpeg
	media-libs/libpng
	net-misc/curl
	sys-libs/zlib
	x11-libs/libX11
	x11-libs/libXi
	x11-libs/libXmu
	x11-libs/libXt
	x11-proto/xproto
	agg? ( x11-libs/agg )
	cairo? ( x11-libs/cairo )
	opengl?	(
		virtual/opengl
		gtk? ( x11-libs/gtkglext )
	)
	ffmpeg?	(
		media-libs/libsdl
		media-video/ffmpeg
	)
	gstreamer? ( !ffmpeg?	(
				media-plugins/gst-plugins-ffmpeg
				media-plugins/gst-plugins-mad
				)
	)
	gtk? (
		dev-libs/atk
		dev-libs/glib
		>x11-libs/gtk+-2
		x11-libs/pango
	)
	kde? ( kde-base/kdelibs )"

DEPEND="${RDEPEND} dev-util/pkgconfig"

pkg_setup() {

	if has_version '<dev-libs/boost-1.34' && ! built_with_use dev-libs/boost threads; then
		eerror "dev-libst/boost has to be built with the 'threads' USE flag"
		die "dev-libs/boost not built with threads"
	fi

	if ! ( use agg || use cairo || use opengl ); then
		eerror "You are trying to build Gnash without choosing a renderer."
		eerror "Please enable one of the following USE flags [agg,cairo,opengl]."
		die "No renderer selected !"
	fi

	if use !ffmpeg && use !gstreamer; then
		eerror "You are trying to build Gnash without choosing a media handler."
		eerror "Please enable one of the following USE flags [ffmpeg,gstreamer]."
		die "No media handler selected !"
	fi

	if use !kde && use !gtk; then
		eerror "You are trying to build Gnash without choosing a gui frontend."
		eerror "Please enable at least one of the following USE flags [gtk,kde]."
		die "No gui frontend selected !"
	fi

        if use nsplugin && ( use kde && use !gtk ); then
                eerror "Building gnash with nsplugin and the kde gui is not supported."
                die "Nsplugin and kde not supported at the same time."
        fi

	if use konqueror && use !kde; then
		eerror "Konqueror plugin requires KDE frontend."
		eerror "Please enable kde USE flag."
		die "KDE required for Konqueror plugin !"
	fi
}

src_compile() {
	./autogen.sh
	local myconf

	# Set nsplugin install directory.

        use nsplugin && myconf="${myconf} --with-plugindir=/opt/netscape/plugins"

	# Set rendering engine.

	if use agg; then
		myconf="${myconf} --enable-renderer=agg"
	elif use opengl; then
		myconf="${myconf} --enable-renderer=ogl"
	else
		myconf="${myconf} --enable-renderer=cairo"
	fi

	# Set media handler.

	if use gstreamer && use !ffmpeg; then
		myconf="${myconf} --enable-media=gst"
	else
		myconf="${myconf} --enable-media=ffmpeg"
	fi

	# Set gui.

	if use gtk && use !kde; then
		myconf="${myconf} --enable-gui=gtk"
	elif use kde && use !gtk; then
		myconf="${myconf} --enable-gui=kde"
	else
		myconf="${myconf} --enable-gui=gtk,kde"                     # Use Gnash default of both kde and gtk.
	fi

	econf \
		$(use_enable cygnal cygnal) \
		$(use_enable debug debugger) \
		$(use_enable gnome ghelp) \
		$(use_enable konqueror kparts) \
		$(use_enable nsplugin nsapi) \
		$(use_enable video_cards_i810 i810-lod-bias) \
		${myconf} || die "econf failed"

	# Should the ebuild use parallel compiling ?

	if use parallel; then
		jobs=${MAKEOPTS}
	else
		jobs="-j1"
	fi

        emake ${jobs} || die "emake failed"
}

src_install() {
	emake ${jobs} DESTDIR="${D}" install || die "emake install failed"
	use nsplugin && inst_plugin /opt/netscape/plugins/libgnashplugin.so \
		|| rm -rf "${D}/opt"
	dodoc AUTHORS ChangeLog NEWS README
}

pkg_postinst() {
	ewarn "ALPHA"
	ewarn "gnash is still in heavy development"
	ewarn "please report gnash bugs upstream to the gnash devs"
}