# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-www/gnash/gnash-0.8.0.ebuild,v 1.6 2007/07/23 14:36:24 drac Exp $

WANT_AUTOMAKE="1.9"

inherit nsplugins kde-functions qt3 multilib flag-o-matic autotools
set-kdedir eutils

DESCRIPTION="Gnash is a GNU Flash movie player that supports many SWF v7 features"
HOMEPAGE="http://www.gnu.org/software/gnash"
SRC_URI="mirror://gnu/${PN}/${PV}/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="agg cairo opengl gtk kde konqueror gstreamer ffmpeg nsplugin xml video_cards_i810"

RDEPEND="
	agg? ( >=x11-libs/agg-2.5 )
	cairo? ( x11-libs/cairo )
	opengl? ( 
		virtual/opengl 
		gtk? (
			x11-libs/gtkglext
		)
	)
	gtk? ( 
		>x11-libs/gtk+-2
		x11-libs/pango
		dev-libs/glib
		dev-libs/atk
	)
	kde? ( kde-base/kdelibs )
	xml? ( dev-libs/libxml2 )
	sys-libs/zlib
	media-libs/jpeg
	media-libs/libpng
	net-misc/curl
	mysql? ( virtual/mysql )
	ffmpeg? ( media-video/ffmpeg )
	gstreamer? ( 
		media-libs/gstreamer
		|| (
			media-plugins/gst-plugins-ffmpeg
			media-plugins/gst-plugins-mad
		)
	)
	!gstreamer? ( 
		!ffmpeg? ( 
			media-libs/libsdl 
		)
	)
	dev-libs/boost
	x11-libs/libX11
	x11-libs/libXi
	x11-libs/libXmu
	x11-libs/libXt
	x11-proto/xproto
	"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

pkg_setup() {
	if ! ( use agg || use opengl || use cairo ); then
		eerror "Select one renderer between: agg, opengl or cairo."
		die "opengl, agg or cairo flag needed"
	fi

	if has_version '<dev-libs/boost-1.34' && ! built_with_use dev-libs/boost threads; then
		eerror "dev-libst/boost has to be built with the 'threads' USE flag"
		die "dev-libs/boost not built with threads"
	fi

	if use !ffmpeg && use !gstreamer; then
		eerror "You are trying to build Gnash without choosing a media handler."
		eerror "Please enable one of the following ffmpeg, gstreamer or mad (mp3 audio only)."
		die "No media handler selected !"
	fi

	if use !kde && use !gtk; then
		eerror "You are trying to build Gnash without choosing a frontend."
		eerror "Please enable kde or gtk USE flag."
		die "No frontend selected !"
	fi

	if use nsplugin && use !gtk; then
		eerror "Firefox plugin requires GTK frontend."
		eerror "Please enable gtk USE flag."
		die "GTK required for plugin !"
	fi

	if use konqueror && use !kde; then
		eerror "Konqueror plugin requires KDE frontend."
		eerror "Please enable kde USE flag."
		die "KDE required for plugin !"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	./autogen.sh
	eautoconf
	eautomake
}

src_compile() {
	local myconf
	local gui
	local extensions

	use nsplugin && myconf="${myconf} --with-plugindir=/opt/netscape/plugins"

	if use !nsplugin; then
		myconf="${myconf} --disable-nsapi"
	fi

	if use !konqueror; then
		myconf="${myconf} --disable-kparts"
	fi

	if use agg; then
		myconf="${myconf} --enable-renderer=agg"
	fi
	if use cairo; then
		myconf="${myconf} --enable-renderer=cairo"
	fi
	if use opengl; then
		myconf="${myconf} --enable-renderer=ogl"
	fi

	if use gtk; then
		gui="gtk";
	fi

	if use kde; then
		gui="${gui},kde";
	fi

	if use gstreamer && use !ffmpeg; then
		myconf="${myconf} --enable-media=gst"
	fi

	if use ffmpeg; then
		myconf="${myconf} --enable-media=ffmpeg"
	fi


	econf \
		$(use_enable nsplugin plugin) \
		$(use_enable xml) \
		$(use_enable video_cards_i810 i810-lod-bias) \
		--enable-gui=${gui} \
		--without-gcc-arch --disable-debugger \
		${myconf} || die "econf failed"
	emake -j1 || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	use nsplugin && inst_plugin /opt/netscape/plugins/libgnashplugin.so \
		|| rm -rf "${D}/opt"
	dodoc AUTHORS ChangeLog NEWS README
}

pkg_postinst() {
	ewarn "ALPHA"
	ewarn "gnash is still in heavy development"
	ewarn "please report gnash bugs upstream to the gnash devs"
}