# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libfwbuilder/libfwbuilder-2.1.10.ebuild,v 1.1 2007/04/01 20:09:14 anant Exp $

inherit eutils qt3

DESCRIPTION="Firewall Builder 2.0 API library and compiler framework"
HOMEPAGE="http://www.fwbuilder.org/"
SRC_URI="mirror://sourceforge/fwbuilder/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="lwres snmp ssl stlport"

DEPEND=">=dev-libs/libxml2-2.4.10
	>=dev-libs/libxslt-1.0.7
	lwres? ( =net-dns/bind-9* )
	snmp? ( net-analyzer/net-snmp )
	ssl? ( dev-libs/openssl )
	stlport? ( dev-libs/STLport )
	$(qt_min_version 3)"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-gcc42.patch
}

src_compile() {
	# we want to use our eqmake instead of bundled script to process qmake files
	sed -i -e 's:. ./runqmake.sh:echo:' configure || die "sed failed"

	econf   $(use_with lwres lwres) \
		$(use_with ssl openssl) \
		$(use_with snmp ucdsnmp) \
		$(use_with stlport stlport) \
		--with-advanced-dns \
		|| die "configure failed"

	# use eqmake to generate Makefiles
	eqmake3 ${PN}.pro
	for subdir in src src/fwbuilder src/fwcompiler src/test src/confscript etc doc migration; do
		eqmake3 "${subdir}/${subdir##*/}.pro" -o ${subdir}/Makefile
	done

	emake || die "make failed"
}

src_install() {
	make install DDIR="${D}" || die "make install failed"

	cd "${D}"/usr/share/doc/${PF}
	rm COPYING INSTALL
	prepalldocs
}