# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic games

S="${WORKDIR}/${P}"
DESCRIPTION="An online MMORPG written in C and SDL"
HOMEPAGE="http://www.eternal-lands.com"
SRC_URI="mirror://gentoo/${P}.tar.bz2
	mirror://gentoo/eternal-lands.png"

# NOTE: Sometimes you'll have to roll your own elc tarball from their CVS tree
# as they don't always release one. If they do then use this in SRC_URI.
# Also, they don't always name the source packages the same, but this should
# be close.

# MY_PV="${PV//_/}"
# MY_PV="${MY_PV//./}"
# ftp://ftp.berlios.de/pub/elc/elc_${MY_PV}.tgz

LICENSE="eternal_lands"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd"
IUSE="debug doc map-editor kernel_linux"

RDEPEND="x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXdmcp
	x11-libs/libXext
	virtual/opengl
	>=media-libs/libsdl-1.2.5
	>=media-libs/sdl-net-1.2.5
	>=media-libs/sdl-image-1.2.5
	media-libs/openal
	media-libs/freealut
	media-libs/libvorbis
	>=dev-libs/libxml2-2.6.7
	media-libs/cal3d
	!=media-libs/cal3d-0.11.0_pre20050823
	>=media-libs/libpng-1.2.8
	~games-rpg/${PN}-data-${PV}"

DEPEND="${RDEPEND}
	app-arch/unzip
	doc? ( >=app-doc/doxygen-1.3.8
		>=media-gfx/graphviz-1.10 )"

pkg_setup() {
	games_pkg_setup
	if built_with_use media-libs/cal3d 16bit-indices ; then
		eerror "${PN} won't work if media-libs/cal3d has been built with 16bit-indices"
		die "re-emerge  media-libs/cal3d without the 16bit-indices USE flag"
	fi
}

src_unpack() {
	OPTIONS="-DDATA_DIR="\\\\\"${GAMES_DATADIR}/${PN}/\\\\\"""
	S_CLIENT="${WORKDIR}/elc"
	BROWSER="firefox"

	unpack ${A}
	cd "${S}"

	# Run patches
	patch -p1 < ${FILESDIR}/eternal-lands-1.4.0.Makefiles.patch \
		|| die "patch failed"

	# We need to make sure we fail on implicit declarations.
	# OPTIONS="${OPTIONS} -Werror-implicit-function-declaration"

	# Add debugging options
	if use debug ; then
		OPTIONS="${OPTIONS} -DMEMORY_DEBUG"
		append-flags -ggdb
	fi

	# Clean compile flags (make Gentoo friendly)
	sed -i \
		-e "s@CFLAGS=\$(PLATFORM) \$(CWARN) -O0 -ggdb -pipe@CFLAGS = ${CFLAGS} ${OPTIONS} @g" \
		-e "s@CXXFLAGS=\$(PLATFORM) \$(CXXWARN) -O0 -ggdb -pipe@CXXFLAGS = ${CXXFLAGS} ${OPTIONS} @g" \
		-e 's/lopenal/lopenal -l alut/' \
		elc/Makefile.linux || die "sed failed"

	sed -i \
		-e 's/#browser/browser/g' \
		-e "s/browser = mozilla/#browser = ${BROWSER}/g" \
		-e "s@#data_dir = /usr/local/games/el/@#data_dir = ${GAMES_DATADIR}/${PN}/@g" \
		elc/el.ini || die "sed failed"

	# Support BSD in the Linux makefile - it's easier
	use kernel_linux || sed -i \
		-e 's/^CFLAGS=.*/& -DBSD/' \
		elc/Makefile.linux || die "sed failed"

	# Gah (anybody know why this is here?)
	sed -i \
		-e 's/CXX=g++/CXX=gcc/' \
		elc/Makefile.linux || die "sed failed"

	# Finally, update the server
	sed -i -e '/#server_address =/ s/.*/#server_address = game.eternal-lands.com/' \
		elc/el.ini || die "sed failed"

	if use map-editor; then
		# I think it's safe to use the same OPTIONS as for the client
		sed -i \
			-e "s@OPTIONS=@OPTIONS = ${CFLAGS} ${OPTIONS} @g" \
			-e 's/-mcpu=i686 -O3 -fomit-frame-pointer //g' \
			map_editor/Makefile.linux || die "sed failed"
	fi
}

src_compile() {
	emake -C elc -f Makefile.linux || die "make failed"

	if use doc; then
		emake -C elc -f Makefile.linux docs \
			|| die "Failed to create documentation, try with USE=-doc"
		# Move docs so we can get them in a sensible subdir.
		mv elc/docs/html client \
			|| die "Failed to move documentation directory"
	fi

	if use map-editor; then
		emake -C map_editor -f Makefile.linux \
			|| die "make failed"
	fi
}

src_install() {
	doicon "${DISTDIR}/eternal-lands.png" ${PN}.png

	pushd elc
	newgamesbin el.x86.linux.bin el \
		|| die "newgamesbin failed"
	make_desktop_entry el "Eternal Lands" \
		|| die "make_desktop_entry failed"
	popd

	if use map-editor; then
		pushd map_editor
		newgamesbin mapedit.x86.linux.bin el-mapeditor \
			|| die "newgamesbin failed"
		make_desktop_entry el-mapeditor "Eternal Lands Map Editor" \
			|| die "make_desktop_entry failed"
		popd
	fi

	insopts -m 0660
	insinto "${GAMES_DATADIR}/${PN}"

	pushd elc
	doins -r *.ini *.txt commands.lst \
		|| die "doins failed"
	popd

	if use doc ; then
		dohtml -r client/*
	fi

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	elog "Auto Update is now enabled in Eternal Lands"
	elog "If an update occurs then the client will suddenly exit"
	elog "Updates only happen when the game first loads"
	elog "Please don't report this behaviour as a bug"

	# Ensure that the files are writable by the game group for auto
	# updating.
	chmod -R g+rw "${ROOT}/${GAMES_DATADIR}/${PN}"

	# Make sure new files stay in games group
	find "${ROOT}/${GAMES_DATADIR}/${PN}" -type d -exec chmod g+sx {} \;
}