quake4-bin-1.4.2.ebuild

quake4-bin-1.4.2.ebuild (text/plain), 3.10 KB, created by Paul Bredbury on 2007-06-19 14:50:29 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

if [[ "${PV:0-5}" = "_beta" ]] ; then
	MY_PV=${PV/_beta}
	MY_PV=beta-${MY_PV}
else
	MY_PV=${PV}
fi

DESCRIPTION="Sequel to Quake 2, an id Software 3D first-person shooter"
HOMEPAGE="http://www.quake4game.com/"
SRC_URI="mirror://idsoftware/quake4/linux/quake4-linux-${MY_PV}.x86.run"

LICENSE="QUAKE4"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="alsa cdinstall clean-icon dedicated opengl smp"
RESTRICT="strip"

UIDEPEND="virtual/opengl
	x86? (
		x11-libs/libXext
		x11-libs/libX11
		x11-libs/libXau
		x11-libs/libXdmcp
		media-libs/libsdl )
	amd64? (
		app-emulation/emul-linux-x86-sdl
		app-emulation/emul-linux-x86-xlibs
		|| (
			>=app-emulation/emul-linux-x86-xlibs-7.0
			x11-drivers/nvidia-drivers
			x11-drivers/nvidia-legacy-drivers
			>=x11-drivers/ati-drivers-8.8.25-r1 ) )
	alsa? ( >=media-libs/alsa-lib-1.0.6 )"

RDEPEND="sys-libs/glibc
	dedicated? ( app-misc/screen )
	amd64? ( app-emulation/emul-linux-x86-baselibs )
	opengl? ( ${UIDEPEND} )
	cdinstall? ( games-fps/quake4-data )
	!dedicated? ( !opengl? ( ${UIDEPEND} ) )"
DEPEND="clean-icon? ( media-gfx/imagemagick )"

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/quake4
Ddir=${D}/${dir}

GAMES_CHECK_LICENSE="yes"

QA_TEXTRELS="${dir:1}/pb/pbag.so
	${dir:1}/pb/pbags.so
	${dir:1}/pb/pbcl.so
	${dir:1}/pb/pbcls.so
	${dir:1}/pb/pbsv.so
	${dir:1}/libSDL-1.2.id.so.0"
QA_EXECSTACK="${dir:1}/quake4.x86
	${dir:1}/quake4smp.x86
	${dir:1}/q4ded.x86
	${dir:1}/libgcc_s.so.1
	${dir:1}/libSDL-1.2.id.so.0
	${dir:1}/libstdc++.so.6"

src_unpack() {
	unpack_makeself ${A}

	mv q4icon.bmp quake4.bmp || die
}

src_install() {
	insinto "${dir}"
	doins *.{htm,txt} README us/version.info || die "docs"
	doins -r pb q4mp || die "doins pb q4mp"

	exeinto "${dir}"
	doexe openurl.sh || die "openurl.sh"
	doexe bin/Linux/x86/{quake4{,smp}.x86,q4ded.x86,*.so.?} \
		|| die "doexe x86 exes/libs"

	insinto "${dir}"/q4base
	doins q4base/* us/q4base/* || die "doins q4base"
	if use dedicated ; then
		games_make_wrapper quake4-ded ./q4ded.x86 "${dir}" "${dir}"
	fi

	if use opengl || ! use dedicated ; then
		local exe="quake4.x86"
		use smp && exe="quake4smp.x86"
		games_make_wrapper quake4 "./${exe}" "${dir}" "${dir}"

		if use clean-icon ; then
			# Remove pink background
			convert -transparent magenta quake4.bmp{,} || die "convert"
		fi
		doicon quake4.bmp || die "doicon"
		make_desktop_entry quake4 "Quake IV" /usr/share/pixmaps/quake4.bmp
	fi

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	if ! use cdinstall ; then
		elog "You need to copy pak001.pk4 through pak012.pk4, along with"
		elog "zpak*.pk4 from either your installation media or your hard drive"
		elog "to ${dir}/q4base before running the game."
		echo
	fi
	if use opengl || ! use dedicated ; then
		elog "To play the game, run:  quake4"
		elog
		# The default language is Spanish!
		elog "To reset the language from Spanish to English, run:"
		elog " sed -i 's:spanish:english:' ~/.quake4/q4base/Quake4Config.cfg"
		elog
		elog "Saved games from previous Quake 4 versions might not be compatible."
		echo
	fi
}