openbox-3.3.995.ebuild (forgot gettext depend)

openbox-3.3.995.ebuild (text/plain), 1.22 KB, created by Bill Good on 2007-06-02 21:45:00 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="A standards compliant, fast, light-weight, extensible window
manager."
HOMEPAGE="http://icculus.org/openbox/"
SRC_URI="http://icculus.org/openbox/releases/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="3"
KEYWORDS="~x86"
IUSE="nls startup-notification xcursor xinerama"

RDEPEND=">=dev-libs/glib-2
	>=dev-libs/libxml2-2.0
	>=media-libs/fontconfig-2
	virtual/xft
	x11-libs/libXrandr
	x11-libs/libXt
	x11-libs/pango
	nls? ( sys-devel/gettext )
	startup-notification? ( x11-libs/startup-notification )
	xcursor? ( x11-libs/libXcursor )
	xinerama? ( x11-libs/libXinerama )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	x11-proto/xextproto
	x11-proto/xf86vidmodeproto
	xinerama? ( x11-proto/xineramaproto )"

src_compile() {
	econf \
		$(use_enable nls) \
		$(use_enable startup-notification) \
		$(use_enable xcursor) \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	dodir /etc/X11/Sessions
	echo "/usr/bin/openbox-session" > "${D}/etc/X11/Sessions/${PN}"
	fperms a+x /etc/X11/Sessions/${PN}

	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc ABOUT-NLS AUTHORS CHANGELOG COMPLIANCE README
}