# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/monodevelop/monodevelop-0.12.ebuild,v 1.3 2006/12/11 01:03:43 compnerd Exp $

inherit mono eutils fdo-mime autotools

DESCRIPTION="Free .NET development environment"
SRC_URI="http://www.go-mono.com/sources/${PN}/${P}.tar.gz"
HOMEPAGE="http://monodevelop.com/"
LICENSE="GPL-2"

IUSE="boo java nemerle aspnet subversion vte firefox seamonkey"
DEPEND=">=dev-dotnet/gtksourceview-sharp-0.10
	>=dev-dotnet/gecko-sharp-0.10
	>=dev-lang/mono-1.1.10
	>=dev-util/monodoc-1.0
	>=dev-dotnet/gtk-sharp-2.4.0
	>=dev-dotnet/gnomevfs-sharp-2.4.0
	>=dev-dotnet/gnome-sharp-2.4.0
	>=dev-dotnet/gconf-sharp-2.4.0
	>=dev-dotnet/gtkhtml-sharp-2.4.0
	>=dev-dotnet/glade-sharp-2.4.0
	boo? ( >=dev-lang/boo-0.7.6 )
	java? ( || ( >=dev-dotnet/ikvm-bin-0.14 >=dev-dotnet/ikvm-0.14.0.1-r1 ) )
	subversion? ( dev-util/subversion )
	nemerle? ( || (
		( >=dev-lang/nemerle-0.9.3.99 <=dev-lang/nemerle-0.9.3.99.6855 )
		( >=dev-lang/nemerle-dev-0.9.3.99 <=dev-lang/nemerle-dev-0.9.3.99.6855 ) ) )
	aspnet? ( dev-dotnet/xsp >=dev-dotnet/jscall-sharp-0.0.2_pre20061125 )
	vte? ( >=dev-dotnet/vte-sharp-2.4.0 )
	firefox? ( || ( www-client/mozilla-firefox www-client/mozilla-firefox-bin ) )
	seamonkey? ( || ( www-client/seamonkey www-client/seamonkey-bin ) )"

KEYWORDS="~x86"
SLOT="0"

src_unpack() {
	unpack ${A}
	cd ${S}

	# Changes to Makefile.am
	epatch ${FILESDIR}/monodevelop-0.12-makeinstall-fix.diff
	epatch ${FILESDIR}/monodevelop-0.13.1-nemerle-fix.diff
	export WANT_AUTOCONF=2.5 WANT_AUTOMAKE=1.9
	eautoreconf
}

src_compile() {

	local conf
	conf="$(use_enable boo) \
		$(use_enable java) \
		$(use_enable nemerle) \
		--enable-nunit \
		--enable-versioncontrol \
		$(use_enable subversion) \
		--enable-monoextensions \
		--disable-update-mimedb \
		--disable-update-desktopdb"

	# enable ASP.NET Project and Visual Designer
	if use aspnet; then
		ewarn "ASP.NET Visual Designer is still in an early stage of development,"
		ewarn "and can not work correctly."
		einfo "For more infos go here: http://www.mono-project.com/AspNetEdit"
		echo
		ebeep 3
		conf="${conf} $(use_enable aspnet) --enable-aspnetedit"
	fi

	econf ${conf} || die "configure failed"

	emake -j1 || die
}

src_install () {
	emake DESTDIR=${D} install || die

	# configure Add-in dirs
	ASPNETEDIT_DIR="${D}/usr/$(get_libdir)/monodevelop/AddIns/AspNetEdit"
	SEAMONKEY_CHROME="${D}/usr/$(get_libdir)/seamonkey/chrome"
	FIREFOX_CHROME="${D}/usr/$(get_libdir)/mozilla-firefox/chrome"
	
	mkdir -p ${ASPNETEDIT_DIR}
	cp Extras/AspNetEdit/chrome/aspdesigner.jar ${ASPNETEDIT_DIR}

	if use seamonkey; then
		mkdir -p ${SEAMONKEY_CHROME}
		cp Extras/AspNetEdit/chrome/aspdesigner.manifest ${SEAMONKEY_CHROME}
	fi
	if use firefox; then
		mkdir -p ${FIREFOX_CHROME}
		cp Extras/AspNetEdit/chrome/aspdesigner.manifest ${FIREFOX_CHROME}
	fi

	dodoc ChangeLog README
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}