# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils subversion linux-info linux-mod

DESCRIPTION="Experimental driver for RTL8187 and RTL818x wireless chipsets"
HOMEPAGE="http://rtl-wifi.sourceforge.net/"
SRC_URI=""

ESVN_REPO_URI="https://rtl-wifi.svn.sourceforge.net/svnroot/rtl-wifi"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND=""

S=${WORKDIR}

MODULE_NAMES="ieee80211_crypt-rtl(net:${S}/ieee80211)
	ieee80211_crypt_wep-rtl(net:${S}/ieee80211)
	ieee80211_crypt_tkip-rtl(net:${S}/ieee80211)
	ieee80211_crypt_ccmp-rtl(net:${S}/ieee80211)
	ieee80211-rtl(net:${S}/ieee80211)
	r8187(net:${S}/rtl8187-newstack)
	r8180(net:${S}/rtl818x-newstack)"
BUILD_TARGETS="all"

pkg_setup() {
	if ! kernel_is 2 6 ; then
		eerror "This driver is for kernel >=2.6 only!"
		die "No kernel >=2.6 detected!"
	fi

	linux-info_pkg_setup
	linux-mod_pkg_setup

	# Needs NET_RADIO in kernel, for wireless_send_event
	local CONFIG_CHECK="NET_RADIO CRYPTO CRYPTO_ARC4 CRC32 !IEEE80211"
	local ERROR_IEEE80211="${P} requires the in-kernel version of the IEEE802.11 subsystem to be disabled (CONFIG_IEEE80211)"
	check_extra_config
}

src_install() {
	linux-mod_src_install

	dodoc ChangeLog

	# Further documentation
	local d f
	for d in ieee80211 rtl8180-sa2400-dev rtl8187-dev rtl818{7,x}-newstack ; do
		docinto "${d}"
		for f in AUTHORS CHANGES README{,.adhoc,.master} ; do
			[[ -e "${d}/${f}" ]] && dodoc "${d}/${f}"
		done
	done
}

pkg_postinst() {
	linux-mod_pkg_postinst

	elog "You may want to add the following modules to"
	elog "/etc/modules.autoload.d/kernel-2.6"
	elog
	elog "The module itself:       r8180 or r8187"
	elog "WEP and WPA encryption:  ieee80211_crypt-rtl"
	elog "WEP encryption:          ieee80211_crypt_wep-rtl"
	elog "WPA TKIP encryption:     ieee80211_crypt_tkip-rtl"
	elog "WPA CCMP encryption:     ieee80211_crypt_ccmp-rtl"
	elog "For the r8187 module:    ieee80211-rtl"
}