# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

GCONF_DEBUG="no"
SCROLLKEEPER_UPDATE="no"

inherit gnome2

DESCRIPTION="Fyre renders and animates Peter de Jong maps"
SRC_URI="http://flapjack.navi.cx/releases/${PN}/${P}.tar.bz2"
HOMEPAGE="http://fyre.navi.cx/"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
IUSE="cluster openexr"

RDEPEND=">=gnome-base/libglade-2.4
	cluster? ( >=net-libs/gnet-2.0 )
	openexr? ( media-libs/openexr )"

DEPEND="${RDEPEND}
	dev-util/desktop-file-utils
	>=dev-util/pkgconfig-0.9
	x11-misc/shared-mime-info"

src_compile() {
	econf \
		--disable-dependency-tracking \
		$(use_enable cluster gnet) \
		$(use_enable openexr) \
		|| die "econf failed"

	emake || die "emake failed"
}

src_install() {
	make DESTDIR=${D} \
		update_xdgmime=/bin/true update_fdodesktop=/bin/true \
		install || die "install failed"
	dodoc AUTHORS ChangeLog README TODO

	if use cluster; then
		insinto /etc/conf.d
		newins "${FILESDIR}/${P}-conf" fyre
		exeinto /etc/init.d
		newexe "${FILESDIR}/${P}-init" fyre
	fi
}