# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit vim-plugin

DESCRIPTION="vim plugin: CVS, SVN and SVK integration plugin"
HOMEPAGE="http://www.vim.org/scripts/script.php?script_id=90"
SRC_URI="http://hawking.nonlogic.org/distfiles/${P}.tar.bz2"

LICENSE="public-domain"
KEYWORDS="~x86"
IUSE="cvs subversion svk"

DEPEND="|| ( >=app-editors/vim-7.0
	>=app-editors/gvim-7.0 )"
RDEPEND="${DEPEND}
	cvs? ( dev-util/cvs )
	subversion? ( dev-util/subversion )
	svk? ( dev-util/svk )
	!app-vim/cvscommand
	!app-vim/calendar" # conflict, bug 626777

VIM_PLUGIN_HELPFILES="vcscommand-contents"

no_flags_die() {
	eerror ""
	eerror "Please choose at least one VCS system"
	eerror "to be supported by this plugin"
	eerror ""
	eerror " Valid useflags are;"
	eerror " cvs, subversion, svk"
	die "No vcs systems set"
}

pkg_setup() {
	elog "Note:	Support for all VCS systems are enabled by use flags."
	elog "		Make sure you've enabled the flags you want."
	elog ""

	use cvs || use subversion || use svk || no_flags_die
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	use cvs || rm syntax/CVSAnnotate.vim plugin/vcscvs.vim
	use subversion || rm syntax/SVNAnnotate.vim plugin/vcssvn.vim
	use svk || rm syntax/SVKAnnotate.vim plugin/vcssvk.vim
}