# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PN="lostlabyrinth"
DESCRIPTION="Lost Labyrinth, a Rogue-like game"
HOMEPAGE="http://www.lostlabyrinth.com/"
SRC_URI="mirror://sourceforge/lostlaby/${MY_PN}_${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="strip"
QA_WX_LOAD="${GAMES_PREFIX_OPT:1}/${MY_PN}/laby"
QA_EXECSTACK="${GAMES_PREFIX_OPT:1}/${MY_PN}/laby"

DEPEND=">=media-libs/libsdl-1.2.8-r1
	x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXdmcp
	x11-libs/libXext"

S=${WORKDIR}/laby_${PV}

src_install() {
	local statedir=${GAMES_STATEDIR}/${MY_PN}
	local exe=laby
	local dir=${GAMES_PREFIX_OPT}/${MY_PN}
	local f

	insinto "${statedir}"
	doins highscores.dat settings.txt || die

	insinto "${dir}"
	exeinto "${dir}"
	doins * || die
	doexe ${exe}

	# Set up links for writeable files
	for f in highscores.dat settings.txt savenames.sav laby{1,2,3,4,5,6,7,8,9,10}.sav
	do
		touch "${D}${statedir}/${f}" || die
		rm -f "${D}${dir}/${f}"
		dosym "${statedir}/${f}" "${dir}/${f}" || die
		fperms 660 "${statedir}/${f}" || die
	done

	newicon laby.xpm ${MY_PN}.xpm
	games_make_wrapper ${MY_PN} "${dir}/${exe}" "${dir}"
	make_desktop_entry ${MY_PN} "Lost Labyrinth" ${MY_PN}.xpm

	prepgamesdirs
}