freetype-2.3.0.ebuild

freetype-2.3.0.ebuild (text/plain), 1.86 KB, created by Ron MacNeil on 2007-01-30 04:37:33 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic

DESCRIPTION="A high-quality and portable font engine"
HOMEPAGE="http://www.freetype.org/"
SRC_URI="mirror://sourceforge/freetype/${P/_/}.tar.bz2
	doc? ( mirror://sourceforge/${PN}/${PN}-doc-${PV}.tar.bz2 )"

LICENSE="FTL GPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc-macos ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="zlib bindist doc"

# The RDEPEND below makes sure that if there is a version of moz/ff/tb
# installed, then it will have the freetype-2.1.8+ binary compatibility patch.
# Otherwise updating freetype will cause moz/ff/tb crashes.	 #59849
# 20 Nov 2004 agriffis
DEPEND="zlib? ( sys-libs/zlib )"

RDEPEND="${DEPEND}
	!<www-client/mozilla-1.7.3-r3
	!<www-client/mozilla-firefox-1.0-r3
	!<mail-client/mozilla-thunderbird-0.9-r3
	!<media-libs/libwmf-0.2.8.2"

src_unpack() {

	unpack ${A}

	# Turn on subpixel and bytecode support unless distributing binaries
	# (potential patent issues in the United States)
	# (http://freetype.org/patents.html)
	use bindist || epatch "${FILESDIR}"/freetype-2.3.0-subpixel.patch
	use bindist || epatch "${FILESDIR}"/freetype-2.3.0-bytecode.patch
	use bindist || epatch "${FILESDIR}"/freetype-2.3.0-nounpatentedhinting.patch
	
	# Remove compatibility shims for various packages that (used to)
	# incorrectly rely on freetype internals which have changed in recent
	# versions.
	epatch "${FILESDIR}"/freetype-2.3.0-nocompat.patch

	epunt_cxx

}

src_compile() {

	type -p gmake &> /dev/null && export GNUMAKE=gmake
	econf $(use_with zlib) || die

	emake || die

}

src_install() {

	make DESTDIR="${D}" install || die

	dodoc ChangeLog README
	dodoc docs/{CHANGES,CUSTOMIZE,DEBUG,*.txt,PATENTS,PROBLEMS,TODO}

	cd "${WORKDIR}"/${PN}-doc-${PV}
	use doc && dohtml -r docs/*

}