netscape-flash-9.0.31.0-r1.ebuild

netscape-flash-9.0.31.0.ebuild (text/plain), 1.96 KB, created by Jakub Moc (RETIRED) on 2007-01-17 23:26:38 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit nsplugins

MY_P="install_flash_player_9_linux"
MY_PD="${MY_P/install_}_dev"
DESCRIPTION="Adobe Flash Player"
SRC_URI="http://fpdownload.macromedia.com/get/flashplayer/current/${MY_P}.tar.gz
	    http://download.macromedia.com/pub/flashplayer/updaters/9/${MY_PD}.tar.gz"
HOMEPAGE="http://www.adobe.com/"
IUSE="debug"
SLOT="0"

KEYWORDS="-* ~amd64 ~x86"
LICENSE="AdobeFlash-9.0.31.0"
S=${WORKDIR}
RESTRICT="strip mirror"

DEPEND="!net-www/gplflash
	amd64? ( app-emulation/emul-linux-x86-baselibs
			app-emulation/emul-linux-x86-gtklibs
			app-emulation/emul-linux-x86-soundlibs
			 app-emulation/emul-linux-x86-xlibs )
	x86? ( x11-libs/libXext
		x11-libs/libX11
		x11-libs/libXt
		=x11-libs/gtk+-2*
		media-libs/freetype
		media-libs/fontconfig )"


src_unpack() {
	unpack ${A}
	cd "${S}"/${MY_PD}
	if use debug ; then
		unpack ./plugin/debugger/${MY_P}.tar.gz
		unpack ./standalone/debugger/flashplayer.tar.gz
	else
		unpack ./standalone/release/flashplayer.tar.gz
	fi
}
	
pkg_setup() {
	# This is a binary x86 package => ABI=x86
	# Please keep this in future versions
	# Danny van Dyk <[e-mail]> 2005/03/26
	has_multilib_profile && ABI="x86"
	
	if use debug ; then
		ewarn "You are installing content debugger version of the package."
		ewarn "This is NOT intended for normal use!"
	fi
}

install_plugin() {
	exeinto /opt/netscape/plugins
	doexe libflashplayer.so
	insinto /opt/netscape/plugins
	doins flashplayer.xpt
}

src_install() {
	if use debug ; then
		cd "${S}"/${MY_PD}
		dobin flashplayer || die "dobin failed"
		dodoc README
		cd ${MY_P}
		install_plugin || die "plugin install failed"
	else
		cd "${S}"/${MY_P}
		install_plugin || die "plugin install failed"
		dodoc Readme.txt
		cd "${S}"/${MY_PD}
		dobin flashplayer || die "dobin failed"
	fi
		
	inst_plugin /opt/netscape/plugins/libflashplayer.so
	inst_plugin /opt/netscape/plugins/flashplayer.xpt
}