A better CVS ebuild.

linuxdcpp-9999-r1.ebuild (text/plain), 1.52 KB, created by Togge on 2007-01-17 13:09:01 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo/portage/net-p2p/linuxdcpp/linuxdcpp-9999-r1.ebuild,v 1.1 2006/09/14 05:13:56 naga Exp $

inherit eutils cvs

DESCRIPTION="Direct connect client, looks and works like famous DC++"
HOMEPAGE="http://linuxdcpp.berlios.de"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64 ~sparc"
IUSE="debug"

ECVS_SERVER="cvs.linuxdcpp.berlios.de:/cvsroot/linuxdcpp"
ECVS_MODULE="linuxdcpp"
ECVS_AUTH="pserver"
ECVS_USER="anonymous"

S=${WORKDIR}/${ECVS_MODULE}

RDEPEND=">=gnome-base/libglade-2.4
	>=x11-libs/gtk+-2.6
	app-arch/bzip2"

DEPEND="${RDEPEND}
	dev-util/cvs
	>=dev-util/scons-0.96"


#src_unpack() {
#	cvs_src_unpack ${A}
#}

src_compile() {
	if use debug; then
		scons ${MAKEOPTS} debug=1 PREFIX="/usr" || die "scons build failed."
	else
		scons ${MAKEOPTS} PREFIX="/usr" || die "scons build failed."
	fi
}

src_install() {
	insinto /usr/share/${PN}
	doins ${PN}
	insinto /usr/share/${PN}/pixmaps
	doins pixmaps/*
	insinto /usr/share/${PN}/glade
	doins glade/*

	dodoc Readme.txt Changelog.txt Credits.txt
	dosym /usr/share/${PN}/${PN} /usr/bin/${PN}

	fperms +x /usr/share/${PN}/${PN}

	dosym /usr/share/${PN}/pixmaps/${PN}.png /usr/share/pixmaps/${PN}.png

	make_desktop_entry ${PN} "${PN}" ${PN}.png
}

pkg_postinst() {
	elog
	elog "After adding first directory to shares you might need to restart linuxdcpp."
	elog "UTF-8 is known to cause issues, read /usr/share/doc/${P}/Readme.txt.gz"
	elog "for information."
	elog
}