# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils autotools versionator

IUSE_LINGUAS="linguas_fr"
IUSE="${IUSE_LINGUAS} debug doc emacs gtk profile vim"

DESCRIPTION="GNU Music Typesetter"
SRC_URI="http://download.linuxaudio.org/lilypond/sources/v$(get_version_component_range 1-2)/${P}.tar.gz"
HOMEPAGE="http://lilypond.org/"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86 ~amd64"

RDEPEND=">=dev-scheme/guile-1.6.7
	|| (
		>=app-text/ghostscript-gnu-8.15
		>=app-text/ghostscript-gpl-8.15
		>=app-text/ghostscript-esp-8.15
	)
	virtual/tetex
	>=dev-lang/python-2.4
	>=media-libs/freetype-2
	>=media-libs/fontconfig-2.2.0
	>=x11-libs/pango-1.6.0
	gtk2? ( >=x11-libs/gtk+-2.4 )"

DEPEND="${RDEPEND}
	>=dev-lang/perl-5.8.0-r12
	sys-apps/findutils
	>=sys-apps/texinfo-4.8
	>=sys-devel/flex-2.5.4a-r5
	>=sys-devel/gcc-4.0
	>=sys-devel/make-3.80
	>=app-text/mftrace-1.1.19
	>=media-gfx/fontforge-20060406
	sys-devel/bison
	doc? (
		media-libs/netpbm
		media-gfx/imagemagick
		|| ( >=app-text/ghostscript-gnu-8.54 >=app-text/ghostscript-gpl-8.54 )
	)"

src_unpack() {
	unpack ${A}; cd ${S}

	epatch ${FILESDIR}/${PN}-2.10.8-version.patch
	eautoreconf

	# lilypond python scripts *prepend* /usr/share/lilypond/${PV}/python to
	# sys.path, causing python to attempt to rebuild the pyc, which generates
	# sandbox errors (and is wrong anyway).  Change this policy to use
	# sys.path.append so that PYTHONPATH, set by the Makefiles, takes
	# precendence.
	grep -rlZ sys.path.insert --include \*.py ${S} \
		| xargs -0r sed -i 's/sys.path.insert \?(0, /sys.path.append (/'
	
	if use doc; then
		local mylangs="site"
		use linguas_fr && mylangs="${mylangs}, fr"
		sed -e "s/^LANGUAGES = .*/LANGUAGES = (${mylangs}, )/" \
			-i	buildscripts/langdefs.py || die "sed failed"
	fi
}

src_compile() {
	econf \
		$(use_enable debug debugging) \
		$(use_enable profile profiling) \
		$(use_enable doc documentation) \
		$(use_enable gtk gui) \
		--with-ncsb-dir=/usr/share/fonts/default/ghostscript \
		|| die "econf failed"
	# parallel make errors
	emake -j1 || die "emake failed"

	if use doc; then
		emake -j1 web || die "emake web failed"
	fi
}

src_install () {
	emake install DESTDIR=${D} vimdir=/usr/share/vim/vimfiles \
		|| die "emake install failed"
	
	if use doc; then
		# Note: installs .html docs, .pdf docs and examples
		emake out=www web-install DESTDIR=${D} \
			webdir=/usr/share/doc/${PF}/html || die "emake web-install failed"
	fi

	dodoc AUTHORS.txt ChangeLog COPYING DEDICATION NEWS.txt README.txt THANKS

	use vim || rm -r ${D}/usr/share/vim
	use emacs || rm -r ${D}/usr/share/emacs
}