qt-windows-4.2.2.ebuild

qt-windows-4.2.2.ebuild (text/plain), 5.44 KB, created by Roberto Castagnola on 2007-01-09 13:18:28 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic toolchain-funcs

PATCH_VER="0.3"
EPATCH_SOURCE="${WORKDIR}/qt-${PV}-patches"
EPATCH_SUFFIX="patch"

SRCTYPE="opensource-src"
DESCRIPTION="The Qt toolkit is a comprehensive C++ application development framework."
HOMEPAGE="http://www.trolltech.com/"

SRC_URI="ftp://ftp.trolltech.com/pub/qt/source/qt-x11-${SRCTYPE}-${PV}.tar.gz
	qt-win-addons-${PV}.tar.bz2
	qt-${PV}-patches-${PATCH_VER}.tar.bz2"
S=${WORKDIR}/qt-x11-${SRCTYPE}-${PV}

LICENSE="GPL-2"
SLOT="4"
KEYWORDS="~x86"

IUSE="accessibility debug doc examples gif odbc pch qt3support sqlite3"

# cross-compiling need controlled strip
RESTRICT="strip"

pkg_setup() {
	if ! has_version cross-mingw32/gcc; then
		eerror "cross-mingw32/gcc is needed"
		die "emerge crossdev && crossdev mingw32"
	fi

	CTARGET=mingw32
	PLATFORM=$(qt_mkspecs_dir)
	XPLATFORM="win32-g++"

	QTPREFIXDIR=/usr/${CTARGET}/usr
	QTBASEDIR=${QTPREFIXDIR}/$(get_libdir)/qt4
	QTBINDIR=${QTPREFIXDIR}/bin
	QTLIBDIR=${QTPREFIXDIR}/$(get_libdir)/qt4
	QTPCDIR=${QTPREFIXDIR}/$(get_libdir)/pkgconfig
	QTDATADIR=${QTPREFIXDIR}/share/qt4
	QTDOCDIR=${QTPREFIXDIR}/share/doc/${PF}
	QTHEADERDIR=${QTPREFIXDIR}/include/qt4
	QTPLUGINDIR=${QTDATADIR}/plugins
	QTSYSCONFDIR=/etc/qt4/${CTARGET}
	QTTRANSDIR=${QTDATADIR}/translations
	QTEXAMPLESDIR=${QTDATADIR}/examples
	QTDEMOSDIR=${QTDATADIR}/demos
}

qt_use() {
	useq ${1} && echo "-${1}" || echo "-no-${1}"
	return 0
}

qt_mkspecs_dir() {
	 # Allows us to define which mkspecs dir we want to use.
	local spec

	case ${CHOST} in
		*-freebsd*|*-dragonfly*)
			spec="freebsd" ;;
		*-openbsd*)
			spec="openbsd" ;;
		*-netbsd*)
			spec="netbsd" ;;
		*-darwin*)
			spec="darwin" ;;
		*-linux-*|*-linux)
			spec="linux" ;;
		*)
			die "Unknown CHOST, no platform choosed."
	esac

	CXX=$(tc-getCXX)
	if [[ ${CXX/g++/} != ${CXX} ]]; then
		spec="${spec}-g++"
	elif [[ ${CXX/icpc/} != ${CXX} ]]; then
		spec="${spec}-icc"
	else
		die "Unknown compiler ${CXX}."
	fi

	echo "${spec}"
}

src_unpack() {
	unpack ${A}
	cd ${S}

	epatch

	# Don't let the user go too overboard with flags.  If you really want to, uncomment
	# out the line below and give 'er a whirl.
	strip-flags
	replace-flags -O3 -O2

	# set c/xxflags and ldflags
	sed -i -e "s:QMAKE_CFLAGS_RELEASE.*=.*:QMAKE_CFLAGS_RELEASE=${CFLAGS}:" \
		-e "s:QMAKE_CXXFLAGS_RELEASE.*=.*:QMAKE_CXXFLAGS_RELEASE=${CXXFLAGS}:" \
		-e "s:QMAKE_LFLAGS_RELEASE.*=.*:QMAKE_LFLAGS_RELEASE=${LDFLAGS}:" \
		mkspecs/${PLATFORM}/qmake.conf mkspecs/${XPLATFORM}/qmake.conf mkspecs/common/g++.conf

	# Do not link with -rpath. See bug #75181.
	sed -i -e "s:QMAKE_RPATH.*=.*:QMAKE_RPATH=:" \
		mkspecs/${PLATFORM}/qmake.conf mkspecs/common/g++.conf

	# Replace X11R6/ directories, so /usr/X11R6/lib -> /usr/lib
	sed -i -e "s:X11R6/::" mkspecs/${PLATFORM}/qmake.conf mkspecs/common/linux.conf
}

src_compile() {
	export PATH="${S}/bin:${PATH}"
	export LD_LIBRARY_PATH="${S}/lib:${LD_LIBRARY_PATH}"

	[ $(get_libdir) != "lib" ] && myconf="${myconf} -L/usr/$(get_libdir)"

	myconf="${myconf} -rtti -qt-libpng -qt-libjpeg -qt-libmng -qt-zlib"
	myconf="${myconf} -no-sql-mysql -no-sql-psql -no-sql-ibase -no-sql-sqlite2"
	myconf="${myconf} $(qt_use qt3support) $(qt_use pch)"
	use debug   && myconf="${myconf} -debug -debug-and-release" || myconf="${myconf} -release"
	use odbc	&& myconf="${myconf} -plugin-sql-odbc" || myconf="${myconf} -no-sql-odbc"
	use sqlite3 && myconf="${myconf} -plugin-sql-sqlite" || myconf="${myconf} -no-sql-sqlite"
	use gif		&& myconf="${myconf} -qt-gif" || myconf="${myconf} -no-gif"
	use examples	|| myconf="${myconf} -nomake examples"
	if use accessibility; then
		if [[ "$(gcc-major-version ${CTARGET})" == "4" ]]; then
			einfo "Accessibility support fails to compile with mingw32-g++-4: disabled"
			myconf="${myconf} -no-accessibility"
		else
			myconf="${myconf} -accessibility"
		fi
	else
		myconf="${myconf} -no-accessibility"
	fi

	./configure -stl -verbose -confirm-license -platform ${PLATFORM} -xplatform ${XPLATFORM} \
		-prefix ${QTPREFIXDIR} -bindir ${QTBINDIR} -libdir ${QTLIBDIR} -datadir ${QTDATADIR} \
		-docdir ${QTDOCDIR} -headerdir ${QTHEADERDIR} -plugindir ${QTPLUGINDIR} \
		-sysconfdir ${QTSYSCONFDIR} -translationdir ${QTTRANSDIR} \
		-examplesdir ${QTEXAMPLESDIR} -demosdir ${QTDEMOSDIR} ${myconf} || die

	emake || die
}

src_install() {
	export PATH="${S}/bin:${PATH}"
	export LD_LIBRARY_PATH="${S}/lib:${LD_LIBRARY_PATH}"

	make INSTALL_ROOT=${D} install_subtargets || die
	make INSTALL_ROOT=${D} install_mkspecs || die

	# some *.dll are installed twice (in QTBINDIR and in QTLIBDIR)
	# we want them all in QTBINDIR
	mv -f ${D}/${QTLIBDIR}/*.dll ${D}/${QTBINDIR}

	# 'install_qmake' target is missing
	exeinto ${QTBINDIR}
	doexe ${S}/bin/qmake
	# maybe moc, rcc, uic and qmake programs should be installed elsewhere

	if use doc; then
		make INSTALL_ROOT=${D} install_htmldocs || die
	fi

	# Install the translations.  This may get use flagged later somehow
	make INSTALL_ROOT=${D} install_translations || die

	# controlled strip
	env RESTRICT="" CHOST=${CHOST} prepstrip ${D}/${QTBINDIR}
	env RESTRICT="" CHOST=${CTARGET} prepstrip ${D}/${QTLIBDIR}
	# want to strip dlls too
#	find ${D} -iname "*.dll" -exec $(tc-getSTRIP ${CTARGET}) --strip-unneeded '{}' \;

	cat > "${T}/44qt4-${CTARGET}" << EOF
XQMAKESPEC=${XPLATFORM}
EOF
	doenvd "${T}/44qt4-${CTARGET}"
	# create symlink to use CTARGET-qmake when cross-compiling
	dosym ${QTBINDIR}/qmake /usr/bin/${CTARGET}-qmake
}