# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit distutils

MY_PN='Pylons'
MY_P="${MY_PN}-${PV}"

DESCRIPTION='Pylons Web Framework'
HOMEPAGE='http://www.pylonshq.com'
SRC_URI="http://cheeseshop.python.org/packages/source/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE='BSD'
SLOT='0'
KEYWORDS='~x86'
IUSE='cheetah doc genshi kid'

RDEPEND='>=dev-python/routes-1.6.1
		 >=dev-python/simplejson-1.4
		 >=dev-python/webhelpers-0.2.2
		 >=dev-python/beaker-0.6.2
		 >=dev-python/paste-1.1.1
		 >=dev-python/pastedeploy-1.0
		 >=dev-python/myghty-1.1
		 >=dev-python/formencode-0.6
		 >=dev-python/nose-0.9.1
		 cheetah? ( >=dev-python/turbocheetah-0.9.5 )
		 genshi? ( >=dev-python/genshi-0.3.6 )
		 kid? ( >=dev-python/turbokid-0.9.1 )'

DEPEND='>=dev-python/setuptools-0.6_rc3
		doc? ( >=dev-python/pudge-0.1.2 >=dev-python/buildutils-0.1.2 )'

PYTHON_MODNAME=$MY_PN
S="${WORKDIR}/${MY_P}"

src_compile() {
	distutils_src_compile
	if use doc; then
		einfo 'Generating HTML Documentation -- May take a few minutes'
		$python setup.py pudge || die 'doc generation failed'
	fi
}


src_install() {
	distutils_src_install
	use doc && dohtml -r docs/html/
}