gtk-gnutella-0.96.2.ebuild

gtk-gnutella-0.96.2.ebuild (text/plain), 1.68 KB, created by Hans de Graaff on 2006-10-30 13:35:29 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/gtk-gnutella/gtk-gnutella-0.96.1.ebuild,v 1.6 2006/06/29 13:26:22 wolf31o2 Exp $

inherit eutils

#TODO: headless mode (but not very well tested yet, may still be too hardcore)
IUSE="gnome nls dbus gnutls ipv6 sqlite3"

DESCRIPTION="A GTK+ Gnutella client"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
RESTRICT="nomirror"
HOMEPAGE="http://gtk-gnutella.sourceforge.net/"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="alpha amd64 ppc sparc x86"

DEPEND="dev-libs/libxml2
	|| ( sys-devel/bison dev-util/yacc )
	dbus? ( sys-apps/dbus )
    gnutls? ( net-libs/gnutls )
    sqlite3? ( >=dev-db/sqlite-3.3.0 )
	nls? ( >=sys-devel/gettext-0.11.5 )"

src_compile() {
	local myconf

	if use nls; then
		myconf="${myconf} -Dd_enablenls -Dgmsgfmt=\"/usr/bin/msgfmt\" -Dmsgfmt=\"/usr/bin/msgfmt\""
	else
		myconf="${myconf} -Ud_enablenls"
	fi

	if use dbus; then
		myconf="${myconf} -Ddbus=true"
	else
		myconf="${myconf} -Ddbus=false"
	fi

	if use ipv6; then 
		myconf="${myconf} -Dipv6=true"
	else
		myconf="${myconf} -Dipv6=false"
	fi

	if ! use gnutls; then
		myconf="${myconf} -U d_gnutls"
	fi

	if ! use sqlite3; then
		myconf="${myconf} -U d_sqlite"
	fi

	./Configure -d -s -e \
		-Dprefix="/usr" \
		-Dprivlib="/usr/share/gtk-gnutella" \
		-Dccflags="${CFLAGS}" \
		-Dgtkversion=2 \
		${myconf} \
		-Doptimize=" " \
		-Dofficial="true" || die "Configure failed"

	emake || die "Compile failed"
}

src_install() {
	dodir /usr/bin
	make INSTALL_PREFIX=${D} install || die "Install failed"
	find ${D}/usr/share -type f -exec chmod a-x {} \;
	dodoc AUTHORS ChangeLog README TODO
}