omegat-1.6.0_rc12.ebuild

omegat-1.6.0_rc12.ebuild (text/plain), 1.67 KB, created by MATSUI Tetsushi on 2006-10-28 01:58:47 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils java-pkg

MY_PV=${PV/rc12/RC12a}

DESCRIPTION="Open source computer assisted translation (CAT) tool written in Java."
HOMEPAGE="http://www.omegat.org/"
SRC_URI="mirror://sourceforge/omegat/OmegaT_src_${MY_PV}.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="
	>=virtual/jdk-1.4
	dev-java/ant-core
	app-arch/unzip
"
RDEPEND="
	>=virtual/jre-1.4
	dev-java/java-config
"

S=${WORKDIR}
MY_INSTALL_DIR="/opt/${PN}"

# overlay
STRICT=NOMIRROR

src_unpack() {
	unpack ${A}

	# Fix the path for help documents.
	# It's statically set to the user's home directory in the source.
	local helpPath="\/usr\/share\/doc\/${PF}\/html"
	sed -i "s/\(.*HELP_DIR.*=.*\"\)docs\(\".*\)/\1$helpPath\2/g" \
		src/org/omegat/util/OConsts.java
	epatch ${FILESDIR}/1.6.0-helppath.patch
}

src_compile() {
	# If javadoc.additionalparam isn't there, we get an error.
	ant "jar" "-Djavadoc.additionalparam="
}

src_install() {
	mv dist/OmegaT.jar dist/${PN}.jar
	java-pkg_jarinto ${MY_INSTALL_DIR}
	java-pkg_dojar dist/*.jar
	java-pkg_jarinto ${MY_INSTALL_DIR}/lib
	java-pkg_dojar lib/*.jar lib-mnemonics/dist/*.jar

	exeinto /usr/bin
	make_startup_script

	rm -r release/OmegaT* release/win32* release/l10n-project
	docinto ""
	dodoc release/*
	dohtml -r docs/*
	docinto "lib"
	dodoc lib/*.txt

	doicon images/*.ico
	make_desktop_entry ${PN} "OmegaT ${MY_PV}" "/usr/share/pixmaps/OmegaT.ico" "Application;Office"
}

function make_startup_script() {
	echo "#!/bin/bash	

CP=\$(java-config -p ${PN})
java \"\$@\" -classpath \$CP -jar ${MY_INSTALL_DIR}/${PN}.jar" > ${PN}
	doexe ${PN}
}