# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils java-pkg-2 java-ant-2

MY_P=${P/-tools/}
MY_PN=${PN/-tools/}

DESCRIPTION="Optional tool classes and utilities for MX4J"
HOMEPAGE="http://mx4j.sourceforge.net/"
SRC_URI="mirror://sourceforge/${MY_PN}/${MY_P}-src.tar.gz"

# The ${S}/BUILD-HOWTO is a good source for dependencies
# This package could also be built with jdk-1.3; see special
# handling instructions in ${S}/BUILD-HOWTO.

# javamail and jython support is optional but because ant-core puts it in the classpath
# if it is installed we can't force disable it without modifying the build.xml
# and jikes refuses to compile mx4j with javamail support disabled

# Optional jetty support can be enabled after jetty uses java-pkg_dojar to install jars

RDEPEND="=dev-java/mx4j-${PV}*
	=dev-java/bcel-5.1*
	>=dev-java/commons-logging-1.0.4
	dev-java/log4j
	=www-servers/axis-1*
	~dev-java/burlap-3.0.8
	~dev-java/hessian-3.0.8
	>=dev-java/jython-2.1
	=dev-java/servletapi-2.3*
	>=dev-java/sun-jaf-bin-1.0.2
	>=dev-java/sun-javamail-bin-1.3.1"
#    >=www-servers/jetty-4.2
DEPEND="${RDEPEND}
	=virtual/jdk-1.4*
	>=dev-java/ant-1.6
	source? ( app-arch/zip )"
RDEPEND="${RDEPEND}
	=virtual/jre-1.4*"

LICENSE="mx4j"
SLOT="2.1"
KEYWORDS="~x86"
IUSE="doc examples source"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}

	cd "${S}"
	epatch "${FILESDIR}/${P}-split-javadoc-build.patch"

	cd "${S}/lib"
	java-pkg_jar-from bcel bcel.jar
	java-pkg_jar-from commons-logging commons-logging.jar
	java-pkg_jar-from log4j
	java-pkg_jar-from axis-1
	java-pkg_jar-from servletapi-2.3 servlet.jar

	# optionals
#    java-pkg_jar-from jetty org.mortbay.jetty.jar
	java-pkg_jar-from burlap-3.0
	java-pkg_jar-from hessian-3.0.8
	java-pkg_jar-from jython jython.jar
	java-pkg_jar-from sun-jaf-bin activation.jar
	java-pkg_jar-from sun-javamail-bin mail.jar
}

src_compile() {
	eant -f build/build.xml compile.tools $(use_doc javadocs.tools) \
		$(use examples && echo compile.examples)
}

src_install() {
	java-pkg_dojar dist/lib/mx4j-tools.jar
	java-pkg_dowar dist/lib/mx4j-soap.war

	dodoc README
	use doc && java-pkg_dojavadoc dist/docs/api
	use source && java-pkg_dosrc "${S}/src/tools/*"

	if use examples ; then
		java-pkg_dojar dist/examples/mx4j-examples.jar
		dodir /usr/share/doc/${PF}/examples
		cp -r src/examples/mx4j/examples/* "${D}usr/share/doc/${PF}/examples"
	fi
}

pkg_postinst() {
	ewarn
	ewarn "This package is currently built without Jetty support. Jetty support will be"
	ewarn "added when Jetty is brought up-to-date in Portage with the new Java system."
	ewarn "To track Jetty progress, see the following:"
	ewarn
	ewarn "  http://bugs.gentoo.org/show_bug.cgi?id=94452"
	ewarn "  http://bugs.gentoo.org/show_bug.cgi?id=147469"
	ewarn
}