quake1-doe-1.ebuild

quake1-doe-1.ebuild (text/plain), 940 bytes, created by Paul Bredbury on 2006-08-21 00:28:50 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

DESCRIPTION="Dissolution of Eternity mission pack for Quake 1"
HOMEPAGE="http://www.idsoftware.com/games/quake/quake-mp2/"
SRC_URI=""

# See manual.txt
LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86"
IUSE="X"

RDEPEND="games-fps/quake1-data
	X? ( || (
		games-fps/darkplaces
		games-fps/joequake
		games-fps/tenebrae
		games-fps/ezquake-bin
		games-fps/fuhquake-bin ) )"
DEPEND=""

S=${WORKDIR}
dir=${GAMES_DATADIR}/quake1

pkg_setup() {
	games_pkg_setup

	cdrom_get_cds Eternity/ROGUE/PAK0.PAK:rogue/pak0.pak
}

src_install() {
	insinto "${dir}"/rogue
	newins "${CDROM_ROOT}/${CDROM_MATCH}" pak0.pak \
		|| die "newins ${CDROM_MATCH} failed"

	# CDROM_SET starts at 0
	if [[ "${CDROM_SET}" = "0" ]] ; then
		dodoc "${CDROM_ROOT}"/Eternity/*.TXT
	else
		dodoc "${CDROM_ROOT}"/*.txt
	fi

	prepgamesdirs
}