citadel-client version bump

citadel-client-6.82.ebuild (text/plain), 1.26 KB, created by Christopher Hogan on 2006-08-02 02:07:12 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="Citadel text-based client"
HOMEPAGE="http://www.citadel.org/"
SRC_URI="http://easyinstall.citadel.org/citadel-${PV}.tar.gz"
RESTRICT="primaryuri"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc"
IUSE="ssl zlib ncurses"
S=${WORKDIR}/citadel

DEPEND=">=sys-devel/autoconf-2.53
	ssl? ( >=dev-libs/openssl-0.9.6 )
	zlib? ( >=sys-libs/zlib-1.1.4 )
	ncurses? ( sys-libs/ncurses )"

src_compile() {
	#Directory locations borrowed from citadel/debian/rules
	econf \
		--prefix=/usr/sbin \
		--with-sysconfdir=/etc/citadel \
		--with-spooldir=/var/spool/citadel \
		--with-datadir=/var/lib/citadel \
		--with-rundir=/var/run/citadel \
		--with-docdir=/usr/share/doc/${PF} \
		$(use_with ssl openssl) \
		$(use_with zlib) \
		$(use_with ncurses) \
		--without-pam \
		--without-ldap \
		--without-libical \
		--without-db \
		--disable-autologin \
	|| die "./configure failed"

	emake client || die "make failed"
}

src_install() {
	#make install-exec-new install-docs-new has problems.	
	dobin citadel
	insinto /etc/citadel
	doins citadel.rc
	dohtml docs/citadel.html
	dohtml docs/journaling.html
	dodoc ChangeLog README.txt

	prepall
	prepalldocs
}