Plain Text ebuild for 1.2.1

ocfs2-tools-1.2.1.ebuild (text/plain), 2.30 KB, created by Martin Hierling on 2006-06-26 12:20:14 UTC

# Copyright 2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License, v2 or later

inherit flag-o-matic eutils

DESCRIPTION="Support programs for the Oracle Cluster Filesystem 2"
HOMEPAGE="http://oss.oracle.com/projects/ocfs2-tools/"
SRC_URI="http://oss.oracle.com/projects/ocfs2-tools/dist/files/source/v1.2/${P}.tar.gz"

LICENSE="GPL-2"

SLOT="0"
KEYWORDS="-* ~x86"
IUSE="gtk2"

# Restriction should be removed if this ebuild and it's archive is imported into 
# official portage tree.
RESTRICT="nomirror"

DEPEND="virtual/libc
	sys-kernel/linux-headers
	gtk2? (
		>=dev-libs/glib-2.2.3
		>=x11-libs/gtk+-2.0
		>=dev-lang/python-2.0
		>=dev-python/pygtk-2.0
	)
	sys-fs/e2fsprogs
	sys-libs/readline
	"
src_compile() {
	local myconf=""
	myconf="--enable-dynamic-fsck=yes --enable-dynamic-ctl=yes"
	use gtk2 && myconf="${myconf} --enable-ocfs2console=yes" || \
		myconf="${myconf} --enable-ocfs2console=no --disable-gtktest"

	econf --prefix=/ \
		${myconf} \
		|| die "Failed to configure"

	emake -j1 || die "Failed to compile"
}

src_install() {
	# einstall would fail, because make file considers DESTDIR as root, and then
	# adds mandir, sbindir and rest, which einstall sets separately.
	make DESTDIR=${D} install || die "Failed to install"

	doman mkfs.ocfs2/mkfs.ocfs2.8
	doman ocfs2cdsl/ocfs2cdsl.8
	doman ocfs2console/ocfs2console.8
	doman ocfs2_hb_ctl/ocfs2_hb_ctl.8
	doman tunefs.ocfs2/tunefs.ocfs2.8
	dodoc COPYING CREDITS MAINTAINERS README README.O2CB debugfs.ocfs2/README
	dodoc documentation/users_guide.txt documentation/samples/cluster.conf
	dodoc ${FILESDIR}/INSTALL.GENTOO

	# Keep o2cb script in case someone needs it 
	insinto /usr/sbin
	newins ${S}/vendor/common/o2cb.init o2cb
	insinto /etc/default
	newins ${S}/vendor/common/o2cb.sysconfig o2cb

	newinitd ${FILESDIR}/ocfs2.init ocfs2
	newconfd ${FILESDIR}/ocfs2.conf ocfs2

	insinto /etc/ocfs2
	newins ${S}/documentation/samples/cluster.conf cluster.conf

	if [ ! -d /config ]; then 
		keepdir /config
	fi
	if [ ! -d /dlm ]; then
		keepdir /dlm
	fi

	# FIXME - fix the python lib.
	# pythonians wouldn't like this probably, but I couldn't find better
	# solution.
	mv ${D}/lib ${D}/usr
}

pkg_postinst() {
	einfo ""
	einfo "Please read /usr/share/doc/${P}/INSTALL.GENTOO for instruction"
	einfo "about how to install, configure and run ocfs2."
}