New ebuild providing NetLib's CBLAS interface to BLAS

cblas-reference-20030223.ebuild (text/plain), 2.42 KB, created by Adam Piątyszek on 2006-02-15 13:24:09 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils fortran

MyPN="${PN/-reference/}"

DESCRIPTION="C interface to the BLAS"
LICENSE="public-domain"
HOMEPAGE="http://www.netlib.org/blas/"
SRC_URI="http://www.netlib.org/blas/blast-forum/${MyPN}.tgz"

SLOT="0"
IUSE="ifc"
KEYWORDS="~x86"

DEPEND="sys-devel/libtool
	ifc? ( dev-lang/ifc )"

RDEPEND="virtual/blas
	ifc? ( dev-lang/ifc )" # Need ifc runtime libraries

FORTRAN="g77 ifc"

S="${WORKDIR}/CBLAS"

ifc_info() {
	if [ -z "${IFCFLAGS}" ]
	then
		einfo
		einfo "You may want to set some ifc optimization flags by running this"
		einfo "ebuild as, for example, \`IFCFLAGS=\"-O3 -tpp7 -xW\" emerge blas\`"
		einfo "(Pentium 4 exclusive optimizations)."
		einfo
		einfo "ifc defaults to -O2, with code tuned for Pentium 4, but that"
		einfo "will run on any processor."
		einfo
		einfo "Beware that ifc's -O3 is very aggressive, sometimes resulting in"
		einfo "significantly worse performance."
		einfo
		epause 5
	fi
}

src_unpack() {
	unpack ${A}
	epatch "${FILESDIR}"/cblas-gentoo.patch
}

src_compile() {
	if use ifc; then
		FC="ifc"
		FFLAGS="${IFCFLAGS}"
		ifc_info
	else
		FC="g77"
		FFLAGS="${CFLAGS}"
		DEP_LIBS="-lg2c"
	fi

	DEP_LIBS="${DEP_LIBS} -lblas"

	cd "${S}"/src
	make all FC="libtool --mode=compile --tag=F77 ${FC}" FFLAGS="${FFLAGS}" \
		CC="libtool --mode=compile --tag=CC gcc" CFLAGS="${CFLAGS} -DADD_" \
		|| die

	if use ifc; then
		# Intel portability library that provides the etime function
		libtool --tag=F77 --mode=link ${FC} -shared ${FFLAGS} *.lo \
			${DEP_LIBS} -Wl,-soname -Wl,libcblas.so.0 \
			-o libcblas.so.0.0.0 -Vaxlib || die
		ar cru libcblas.a *.o || die
		ranlib libcblas.a || die
	else
		libtool --mode=link --tag=F77 ${FC} ${FFLAGS} -o libcblas.la *.lo \
			-rpath ${DESTTREE}/lib ${DEP_LIBS} || die
	fi
}

src_install() {
	dodir "${DESTTREE}"/lib || die

	cd "${S}"/src

	if use ifc;	then
		strip --strip-unneeded libcblas.so.0.0.0 || die
		strip --strip-debug libcblas.a || die

		exeinto "${DESTTREE}"/lib
		doexe libcblas.so.0.0.0 || die
		dosym libcblas.so.0.0.0 "${DESTTREE}"/lib/libcblas.so.0 || die
		dosym libcblas.so.0.0.0 "${DESTTREE}"/lib/libcblas.so || die

		dolib.a libcblas.a || die
	else
		libtool --mode=install install -s libcblas.la \
			"${D}"/"${DESTTREE}"/lib || die
	fi

	insinto "${DESTTREE}"/include
	doins cblas_f77.h cblas.h || die

	dodoc "${S}"/README || die
}