dev-libs/pwlib/pwlib-1.9.2.ebuild

pwlib-1.9.2.ebuild (text/plain), 1.34 KB, created by Alessandro Guido on 2006-01-20 07:47:53 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

IUSE="alsa debug ieee1394 ipv6 ldap oss sasl sdl ssl v4l v4l2 xml"

DESCRIPTION="Portable Multiplatform Class Libraries"
HOMEPAGE="http://www.ekiga.org"
SRC_URI="http://www.ekiga.org/downloads/sources/${P}.tar.gz"

LICENSE="MPL-1.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"

RDEPEND="alsa? ( media-libs/alsa-lib )
	 ieee1394? ( sys-libs/libraw1394 )
	 ldap? ( net-nds/openldap )
	 sasl? ( dev-libs/cyrus-sasl )
	 sdl? ( media-libs/libsdl )
	 ssl? ( dev-libs/openssl )
	 xml? ( dev-libs/expat )"
DEPEND="${RDEPEND}"

src_compile() {
	local myconf

	epatch ${FILESDIR}/${PV}-*

	myconf="$(use_enable alsa) \
	        $(use_enable debug exceptions) \
	        $(use_enable debug memcheck) \
	        $(use_enable ieee1394 avc) \
	        $(use_enable ieee1394 dc) \
	        $(use_enable ipv6) \
	        $(use_enable ldap openldap) \
	        $(use_enable oss) \
	        $(use_enable sasl) \
	        $(use_enable sdl) \
	        $(use_enable ssl openssl) \
	        $(use_enable v4l) \
	        $(use_enable v4l2) \
	        $(use_enable xml expat)"
	econf ${myconf} || die "configure failed"
	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"
	dodoc ReadMe.txt ReadMe_QOS.txt History.txt
}