nwn-sou-1.65.ebuild

nwn-sou-1.65.ebuild (text/plain), 2.44 KB, created by Keri Harris on 2005-01-21 14:42:20 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games eutils

UPDATEVER=${PV//.}
PATCH_URL_BASE=http://content.bioware.com/neverwinternights/linux/${UPDATEVER}/linuxsouclientupdate1xxto${UPDATEVER}

DESCRIPTION="Neverwinter Nights - Shadows of Undrentide"
HOMEPAGE="http://nwn.bioware.com/downloads/linuxclient.html"
SRC_URI="linguas_fr? ( ${PATCH_URL_BASE}fre.tar.gz )
	linguas_de? ( ${PATCH_URL_BASE}ger.tar.gz )
	linguas_it? ( ${PATCH_URL_BASE}ita.tar.gz )
	linguas_es? ( ${PATCH_URL_BASE}spa.tar.gz )
	!linguas_de? ( !linguas_fr? ( !linguas_es? ( !linguas_it? (
		${PATCH_URL_BASE}eng.tar.gz
	) ) ) )"

LICENSE="NWN-EULA"
SLOT="0"
KEYWORDS="x86 ~amd64"
IUSE=""
RESTRICT="nostrip nomirror"

RDEPEND="games-rpg/nwn"

S="${WORKDIR}/nwn"

pkg_setup() {
	cdrom_get_cds Data_Linux.zip
	games_pkg_setup
}

src_unpack() {
	mkdir ${S}
	cd ${S}
	local zip
	for zip in Data_Shared Language_data Language_update Data_Linux ; do
		zip=${zip}.zip
		echo ">>> Unpacking ${zip} to ${PWD}"
		unzip -qo "${CDROM_ROOT}"/${zip} || die "failure unpacking ${zip}"
	done
	unpack ${A}
	
	# Remove unneeded libSDL and movie files
	rm -fr lib readme-SDL.txt SDL-1.2.5 movies

	# Rename conflicting files
	mv readme.linuxclientupdate.txt readme.linuxsouclientupdate.txt

	# Remove files conflicting with games-rpg/nwn-hotu
	if has_version games-rpg/nwn-hotu ; then
		rm -f data/xp1patch.bif \
			dialog.tlk \
			nwm/Chapter* \
			nwm/Prelude.nwm \
			nwmain \
			nwserver \
			override/* \
			xp1patch.key
	fi
}

src_install() {
	dodir ${GAMES_PREFIX_OPT}
	sed \
		-e "s:GENTOO_USER:${GAMES_USER}:" \
		-e "s:GENTOO_GROUP:${GAMES_GROUP}:" \
		-e "s:GENTOO_DIR:${GAMES_PREFIX_OPT}:" \
		${FILESDIR}/${P}-fixinstall > ${S}/fixinstall
	PROBLEM_FILES=""
	if [ -f ${GAMES_PREFIX_OPT}/nwn/patch.key ]; then
		PROBLEM_FILES="patch.key"
	fi
	if [ -f ${GAMES_PREFIX_OPT}/nwn/data/patch.bif ]; then
		PROBLEM_FILES="${PROBLEM_FILES} data/patch.bif"
	fi
	if [ -f ${GAMES_PREFIX_OPT}/nwn/override/iit_medkit_001.tga ]; then
		PROBLEM_FILES="${PROBLEM_FILES} override/iit_medkit_001.tga"
	fi
	sed -i \
		-e "/aProblemFiles=()/s:aProblemFiles=():aProblemFiles=(${PROBLEM_FILES}):"	\
		${S}/fixinstall
	mv ${S} ${D}/${GAMES_PREFIX_OPT}
}

pkg_postinst() {
	games_pkg_postinst
	einfo "The NWN SoU linux client is now installed."
	einfo "Proceed with the following step in order to get it working:"
	einfo "Run ${GAMES_PREFIX_OPT}/nwn/fixinstall as root"
}