subtitleeditor-0.51.0.ebuild

subtitleeditor-0.51.0.ebuild (text/plain), 1.38 KB, created by Pacho Ramos on 2015-06-07 13:50:08 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/subtitleeditor/subtitleeditor-0.41.1-r1.ebuild,v 1.4 2015/03/30 02:30:31 tetromino Exp $

EAPI=5
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"

inherit gnome2 versionator flag-o-matic

DESCRIPTION="GTK+ subtitle editing tool"
HOMEPAGE="http://home.gna.org/subtitleeditor/"
SRC_URI="http://download.gna.org/${PN}/$(get_version_component_range 1-2)/${P}.tar.gz"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="debug opengl"

RDEPEND="
	app-text/iso-codes
	dev-cpp/cairomm
	dev-cpp/gtkmm:3.0
	dev-libs/glib:2
	dev-libs/libsigc++:2
	>=dev-cpp/libxmlpp-2.20:2.6
	>=app-text/enchant-1.4
	dev-cpp/gstreamermm:1.0
	media-libs/gstreamer:1.0
	media-libs/gst-plugins-base:1.0[pango,X]
	media-libs/gst-plugins-good:1.0
	media-plugins/gst-plugins-meta:1.0
	x11-libs/gtk+:3
	virtual/libintl
	opengl? (
		>=dev-cpp/gtkglextmm-1.2:1.0
		virtual/opengl )
"
# media-libs/gst-plugins-base[pango] needed for text overlay
# media-libs/gst-plugins-base[X] needed for X/Xv video output
DEPEND="${RDEPEND}
	>=dev-util/intltool-0.40
	virtual/pkgconfig
"

src_configure() {
	# Avoid using --enable-debug as it mocks with CXXFLAGS and LDFLAGS
	use debug && append-flags -DDEBUG

	gnome2_src_configure \
		--disable-debug \
		--disable-osx \
		--enable-nls \
		$(use_enable opengl gl)
}