mail-client/geary-0.4.0.ebuild

geary-0.4.0.ebuild (text/plain), 2.09 KB, created by Mark R. Pariente on 2013-10-05 23:24:55 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

VALA_MIN_API_VERSION=0.20

inherit eutils fdo-mime gnome2-utils vala cmake-utils

MY_P=${P/_pre/pr}
DESCRIPTION="A lightweight, easy-to-use, feature-rich email client"
HOMEPAGE="http://www.yorba.org/projects/geary/"
SRC_URI="http://yorba.org/download/geary/${PV:0:3}/${MY_P}.tar.xz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nls"

DEPEND="
	>=app-crypt/libsecret-0.11
	>=dev-db/sqlite-3.7.4:3
	>=dev-libs/glib-2.32.0:2
	>=dev-libs/libgee-0.8.5:0.8
	dev-libs/libunique:3
	>=dev-libs/libxml2-2.7.8:2
	dev-libs/gmime:2.6
	>=media-libs/libcanberra-0.28
	>=net-libs/webkit-gtk-1.10.0:3[introspection]
	!>net-libs/webkit-gtk-2.0.4:3[introspection]
	>=x11-libs/gtk+-3.6.0:3[introspection]
	>=x11-libs/libnotify-0.7.5"
RDEPEND="${DEPEND}
	gnome-base/gsettings-desktop-schemas
	nls? ( virtual/libintl )"
DEPEND="${DEPEND}
	nls? ( sys-devel/gettext )
	$(vala_depend)
	virtual/pkgconfig"

DOCS=( AUTHORS MAINTAINERS README NEWS THANKS )

S=${WORKDIR}/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/${P}-{unity,cflags}.patch

	local i
	if use nls ; then
		if [[ -n "${LINGUAS+x}" ]] ; then
			for i in $(cd po ; echo *.po) ; do
				if ! has ${i%.po} ${LINGUAS} ; then
					sed -i -e "s/\s${i%.po}$//" po/CMakeLists.txt || die
					rm po/${i} || die
				fi
			done
		fi
	else
		sed -i -e 's#add_subdirectory(po)##' CMakeLists.txt || die
	fi

	cmake-utils_src_prepare
	vala_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DDESKTOP_UPDATE=OFF
		-DGSETTINGS_COMPILE=OFF
		-DICON_UPDATE=OFF
		-DVALA_EXECUTABLE="${VALAC}"
		-DWITH_UNITY=OFF
		-DDESKTOP_VALIDATE=OFF
	)

	cmake-utils_src_configure
}

pkg_preinst() {
	gnome2_icon_savelist
	gnome2_schemas_savelist
}

pkg_postinst() {
	elog "For libnotify sounds you will need"
	elog "\"alsa\" or \"pulseaudio\" useflag of media-libs/libcanberra"
	elog "enabled."

	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update
}