Converted ebuild

jack-audio-connection-kit-0.121.3-r1.ebuild (text/plain), 2.04 KB, created by Michał Górny on 2013-05-05 10:04:38 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/jack-audio-connection-kit/jack-audio-connection-kit-0.121.3.ebuild,v 1.15 2013/02/14 16:05:51 aballier Exp $

EAPI=5

AUTOTOOLS_PRUNE_LIBTOOL_FILES=all
inherit autotools-multilib flag-o-matic

DESCRIPTION="A low-latency audio server"
HOMEPAGE="http://www.jackaudio.org"
SRC_URI="http://www.jackaudio.org/downloads/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sh sparc x86 ~amd64-fbsd"
IUSE="3dnow altivec alsa coreaudio doc debug examples mmx oss sse cpudetection pam"

RDEPEND=">=media-libs/libsndfile-1.0.0[${MULTILIB_USEDEP}]
	sys-libs/ncurses
	amd64? ( abi_x86_32? (
		app-emulation/emul-linux-x86-baselibs[development]
	) )
	alsa? ( >=media-libs/alsa-lib-1.0.18[${MULTILIB_USEDEP}] )
	media-libs/libsamplerate[${MULTILIB_USEDEP}]
	!media-sound/jack-cvs
	abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20121202 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( app-doc/doxygen )"
RDEPEND="${RDEPEND}
	alsa? ( sys-process/lsof )
	pam? ( sys-auth/realtime-base )"

PATCHES=(
	"${FILESDIR}/${PN}-sparc-cpuinfo.patch"
	"${FILESDIR}/${PN}-freebsd.patch"
)

src_configure() {
	local myeconfargs=(
		$(use_enable altivec)
		$(use_enable alsa)
		$(use_enable coreaudio)
		$(use_enable debug)
		$(use_enable mmx)
		$(use_enable oss)
		--disable-portaudio
		$(use_enable sse)
		--with-html-dir=/usr/share/doc/${PF}
	)

	# CPU Detection (dynsimd) uses asm routines which requires 3dnow, mmx and sse.
	if use cpudetection && use 3dnow && use mmx && use sse ; then
		einfo "Enabling cpudetection (dynsimd). Adding -mmmx, -msse, -m3dnow and -O2 to CFLAGS."
		myeconfargs+=( --enable-dynsimd )
		append-flags -mmmx -msse -m3dnow -O2
	fi

	use doc || export ac_cv_prog_HAVE_DOXYGEN=false

	autotools-multilib_src_configure
}

src_install() {
	autotools-multilib_src_install

	if use examples; then
		dodoc -r "${S}/example-clients"
		docompress -x /usr/share/doc/${PF}/example-clients
	fi
}