A proposed ebuild supporting multilib ABIs.

flac-1.2.1-r5.ebuild (text/plain), 1.85 KB, created by Karl Lindén on 2013-04-03 22:15:34 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="5"
inherit eutils autotools-multilib

DESCRIPTION="free lossless audio encoder and decoder"
HOMEPAGE="http://flac.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
	mirror://gentoo/${P}-embedded-m4.tar.bz2"

LICENSE="BSD FDL-1.2 GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="3dnow altivec +cxx debug ogg sse static-libs"

RDEPEND="ogg? ( >=media-libs/libogg-1.1.3[${MULTILIB_USEDEP}] )
	abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20130224 )"
DEPEND="${RDEPEND}
	x86? ( dev-lang/nasm )
	!elibc_uclibc? ( sys-devel/gettext )
	virtual/pkgconfig"

PATCHES=(
	"${FILESDIR}/${P}-asneeded.patch"
	"${FILESDIR}/${P}-cflags.patch"
	"${FILESDIR}/${P}-asm.patch"
	"${FILESDIR}/${P}-dontbuild-tests.patch"
	"${FILESDIR}/${P}-dontbuild-examples.patch"
	"${FILESDIR}/${P}-gcc-4.3-includes.patch"
	"${FILESDIR}/${P}-ogg-m4.patch"
	"${FILESDIR}/${P}-no-html-doc.patch"
)

AUTOTOOLS_AUTORECONF="1"

src_prepare() {
	cp "${WORKDIR}"/*.m4 m4 || die

	export AT_M4DIR="m4"
	autotools-multilib_src_prepare
}

src_configure() {
	local myeconfargs=(
		$(use_enable static-libs static)
		--disable-dependency-tracking
		$(use_enable debug)
		$(use_enable sse)
		$(use_enable 3dnow)
		$(use_enable altivec)
		--disable-doxygen-docs
		--disable-xmms-plugin
		$(use_enable cxx cpplibs)
		$(use_enable ogg)
		--disable-examples
	)
	autotools-multilib_src_configure
}

src_install() {
	autotools-multilib_src_install

	dohtml -r doc/html/*
}

src_test() {
	multilib_foreach_abi flac_src_test
}

flac_src_test() {
	pushd "${BUILD_DIR}" > /dev/null || die 
	if [ $UID != 0 ]; then
		emake check || die
	else
		ewarn "Tests will fail if ran as root, skipping."
	fi
	popd > /dev/null || die
}