mpg123-1.42.ebuild

mpg123-1.42.ebuild (text/plain), 910 bytes, created by Atzm Watanabe on 2004-05-04 11:11:13 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit elisp

IUSE="oggvorbis"

DESCRIPTION="Emacs front-end to mpg123 audio player and OggVorbis audio player"
HOMEPAGE="http://www.gentei.org/~yuuji/software/mpg123el/"
SRC_URI="mirror://gentoo/${P}.tar.bz2"

DEPEND="virtual/emacs"
RDEPEND="${DEPEND}
	virtual/mpg123
	media-sound/aumix
	oggvorbis? ( media-sound/vorbis-tools )"

SLOT="0"
LICENSE="freedist"
KEYWORDS="~x86"

S="${WORKDIR}/${P}"

SITEFILE="50mpg123-gentoo.el"

src_compile(){
	${CC} ${CFLAGS} -o tagput tagput.c || die
	${CC} ${CFLAGS} -o id3put id3put.c || die
	elisp-compile *.el
}

src_install(){
	dobin tagput || die
	dobin id3put || die

	elisp-install ${PN} *.el *.elc
	elisp-site-file-install ${FILESDIR}/${SITEFILE}

	dodoc README
}

pkg_postinst(){
	elisp-site-regen
}

pkg_postrm(){
	elisp-site-regen
}