mpich2-1.3.2_p1.ebuild

mpich2-1.3.2_p1.ebuild (text/plain), 3.29 KB, created by Dries Kimpe on 2011-04-08 21:43:08 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/mpich2/mpich2-1.2.1_p1-r1.ebuild,v 1.11 2010/12/19 19:12:06 jlec Exp $

EAPI=2

inherit eutils toolchain-funcs

MY_PV=${PV/_/}
DESCRIPTION="MPICH2 - A portable MPI implementation"
HOMEPAGE="http://www.mcs.anl.gov/research/projects/mpich2/index.php"
SRC_URI="http://www.mcs.anl.gov/research/projects/mpich2/downloads/tarballs/${MY_PV}/${PN}-${MY_PV}.tar.gz"

LICENSE="as-is"
SLOT="0"
KEYWORDS="amd64 hppa ppc ppc64 x86"
IUSE="+cxx debug doc fortran threads romio mpi-threads"

COMMON_DEPEND="dev-libs/libaio
	romio? ( net-fs/nfs-utils )"

DEPEND="${COMMON_DEPEND}
	dev-lang/perl
	sys-devel/libtool"

RDEPEND="${COMMON_DEPEND}
	!sys-cluster/openmpi
	!sys-cluster/lam-mpi"

S="${WORKDIR}"/${PN}-${MY_PV}

pkg_setup() {
	if use mpi-threads && ! use threads; then
		eerror "mpi-threads requires threads use flag to be enabled"
	fi
}

src_prepare() {
	# We need f90 to include the directory with mods, and to
	# fix hardcoded paths for src_test()
	# See https://trac.mcs.anl.gov/projects/mpich2/ticket/1466
	sed -i \
		-e "s,\$(bindir)/,${S}/bin/,g" \
		-e "s,@MPIEXEC@,${S}/bin/mpiexec,g" \
		-e "s,FCFLAGS\( *\)=,FCFLAGS\1?=," \
		$(find ./test/ -name 'Makefile.in') || die
}

src_configure() {
	local c="--enable-shared"
	local romio_conf

	# The configure statements can be somewhat confusing, as they
	# don't all show up in the top level configure, however, they
	# are picked up in the children directories.

	use debug && c="${c} --enable-g=all --enable-debuginfo"

	if ! use mpi-threads; then
		if ! use threads ; then
	    	c="${c} --with-thread-package=none"
		fi
		c="${c} --enable-threads=single"
	fi

	# enable f90 support for appropriate compilers
	case "$(tc-getFC)" in
	    g77)
			c="${c} --disable-fc";;
	esac

	c="${c} --sysconfdir=/etc/${PN}"
	econf ${c} ${romio_conf} \
		--docdir=/usr/share/doc/${PF} \
		--disable-mpe \
		$(use_enable romio) \
		$(use_enable cxx)
}

src_compile() {
	# Oh, the irony.
	# http://wiki.mcs.anl.gov/mpich2/index.php/Frequently_Asked_Questions#Q:_The_build_fails_when_I_use_parallel_make.
	# https://trac.mcs.anl.gov/projects/mpich2/ticket/297
	emake -j1 || die
}

src_test() {
	local rc

	# See https://trac.mcs.anl.gov/projects/mpich2/ticket/1466
	make \
		CC="${S}"/bin/mpicc \
		CXX="${S}"/bin/mpicxx \
		FC="${S}"/bin/mpif77 \
		F90="${S}"/bin/mpif90 \
		FCFLAGS="${FCFLAGS} -I${S}/src/binding/f90/" \
		testing
	rc=$?

	return ${rc}
}

src_install() {
	local f
	# http://wiki.mcs.anl.gov/mpich2/index.php/Frequently_Asked_Questions#Q:_The_build_fails_when_I_use_parallel_make.
	emake -j1 DESTDIR="${D}" install || die

	dodir /usr/share/doc/${PF}
	dodoc COPYRIGHT README CHANGES RELEASE_NOTES || die
	if use romio; then
		newdoc src/mpi/romio/README README.romio || die
	fi

	if ! use doc; then
		rm -rf "${D}"/usr/share/doc/www*
	else
		dodir /usr/share/doc/${PF}/www
		mv "${D}"/usr/share/doc/www*/* "${D}"/usr/share/doc/${PF}/www/
	fi
}

pkg_postinst() {
	elog ""
	elog "MPE2 has been removed from this ebuild and now stands alone"
	elog "as sys-cluster/mpe2."
	elog ""
	elog "The MPD process manager is no longer supported and has been removed."
	elog "For more information see"
	elog "http://wiki.mcs.anl.gov/mpich2/index.php/Using_the_Hydra_Process_Manager"
}