wine-1.1.7

wine-1.1.7.ebuild (text/plain), 3.85 KB, created by Sergey Kondakov on 2008-10-30 01:05:41 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:

inherit eutils flag-o-matic multilib

EAPI="1"
DESCRIPTION="free implementation of Windows(tm) on Unix"
HOMEPAGE="http://www.winehq.org/"
SRC_URI="mirror://sourceforge/${PN}/${PN}-${PV}.tar.bz2
	http://ibiblio.org/pub/linux/system/emulators/${PN}/${PN}-${PV}.tar.bz2
	gecko? ( mirror://sourceforge/wine/wine_gecko-0.1.0.cab )"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
IUSE="alsa capi cups dbus esd +gecko glu gphoto hal jack jpeg cms ldap nas ncurses opengl ssl oss png samba scanner tls truetype xml X +win16 win64"
RESTRICT="test" #72375

RDEPEND="media-fonts/corefonts
	media-libs/fontconfig
	truetype? 	( >=media-libs/freetype-2.0.0 )
	ncurses? 	( >=sys-libs/ncurses-5.2 )
	jack? 		( media-sound/jack-audio-connection-kit )
	dbus? 		( sys-apps/dbus )
	hal? 		( sys-apps/hal )
	X? (	x11-libs/libSM
		x11-libs/libXcomposite
		x11-libs/libXcursor
		x11-libs/libXrandr
		x11-libs/libXi
		x11-libs/libXinerama
		x11-libs/libXmu
		x11-libs/libXrender
		x11-libs/libXxf86vm
		x11-apps/xmessage )
	alsa? 	( media-libs/alsa-lib )
	capi? 	( net-dialup/capisuite )
	esd? 	( media-sound/esound )
	nas? 	( media-libs/nas )
	cups? 	( net-print/cups )
	glu? 	( virtual/glu )
	gphoto? ( media-libs/libgphoto2 )
	opengl? ( virtual/opengl )
	ssl? 	( dev-libs/openssl )
	jpeg? 	( media-libs/jpeg )
	ldap? 	( net-nds/openldap )
	cms? 	( media-libs/lcms )
	png? 	( media-libs/libpng )
	samba? 	( >=net-fs/samba-3.0.25 )
	tls?	( net-libs/gnutls )
	xml? 	( dev-libs/libxml2 dev-libs/libxslt )
	scanner? ( media-gfx/sane-backends )
	amd64? ( app-emulation/emul-linux-x86-baselibs
		X? 	( >=app-emulation/emul-linux-x86-xlibs-2.1 )
		alsa? 	( >=app-emulation/emul-linux-x86-soundlibs-2.1 )
		oss? 	( >=app-emulation/emul-linux-x86-soundlibs-2.1 )
		)"
DEPEND="${RDEPEND}
	X? (
		x11-proto/inputproto
		x11-proto/xextproto
		x11-proto/xf86vidmodeproto
		x11-proto/xineramaproto
		x11-proto/renderproto
	)
	dev-util/pkgconfig
	sys-devel/bison
	sys-devel/flex"

pkg_setup() {
	use alsa || return 0
	if ! built_with_use --missing true media-libs/alsa-lib midi ; then
		eerror "You must build media-libs/alsa-lib with USE=midi"
		die "please re-emerge media-libs/alsa-lib with USE=midi"
	fi

	if use win64; then
		if use amd64 || use ppc64; then
			ewarn "64 bit wine cannot run ordinary 32bit or 16bit code"
			elog "if you want run 16 or 32bit code - reemerge wine without 'win64'-flag"
		else
			ewarn "it seems there no use for 64bit wine on your architecture"
		fi
	fi
}

src_unpack() {
	unpack wine-${PV}.tar.bz2
	cd "${S}"

	sed -i '/^UPDATE_DESKTOP_DATABASE/s:=.*:=true:' tools/Makefile.in
	epatch "${FILESDIR}"/wine-gentoo-no-ssp.patch #66002
	sed -i '/^MimeType/d' tools/wine.desktop || die #117785
}

src_compile() {
	if use amd64 && ! use win64; then
		multilib_toolchain_setup x86
	fi

	econf \
		--sysconfdir=/etc/wine \
		--with-fontconfig \
		$(use_enable win16) \
		$(use_enable win64) \
		$(use_with ncurses curses) \
		$(use_with opengl) \
		$(use_with X x) \
		$(use_with alsa) \
		$(use_with capi) \
		$(use_with cups) \
		$(use_with dbus) \
		$(use_with esd) \
		$(use_with glu) \
		$(use_with gphoto) \
		$(use_with jack) \
		$(use_with jpeg) \
		$(use_with cms cms) \
		$(use_with ldap) \
		$(use_with hal) \
		$(use_with oss) \
		$(use_with ssl openssl) \
		$(use_with nas) \
		$(use_with scanner sane) \
		$(use_with truetype freetype) \
		$(use_with tls gnutls) \
		$(use_with xml) \
		$(use_with xml xslt) \
		|| die "configure failed"

	emake all || die "all"
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc ANNOUNCE AUTHORS README
	if use gecko ; then
		insinto ${ROOT}/usr/share/wine/gecko
		doins "${DISTDIR}"/wine_gecko-*.cab || die
	fi
}

pkg_postinst() {
	elog "~/.wine/config is now deprecated.  For configuration either use"
	elog "winecfg or regedit HKCU\\Software\\Wine"
}