/sci-misc/elmer-fem/elmer-fem-5.4.1.ebuild

elmer-fem-5.4.1.ebuild (text/plain), 1.60 KB, created by Richard Westwell on 2008-05-08 22:45:02 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools eutils

ELMER_ROOT="elmerfem"

DESCRIPTION="Elmer is a collection of finite element programs, libraries, and visualization tools, main fem"
HOMEPAGE="http://www.csc.fi/english/pages/elmer"
SRC_URI="mirror://sourceforge/${ELMER_ROOT}/${ELMER_ROOT}-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="mpi debug"
DEPEND="sys-libs/glibc
	virtual/blas
	virtual/lapack
	sci-libs/arpack
	sci-libs/matc
	sci-libs/elmer-hutiter
	sci-libs/elmer-eio
	sci-libs/elmer-umfpack
	mpi?     ( sys-cluster/mpich2 )"
RDEPEND="${DEPEND}"
# Note this seems to only configure correctly with the elmer version of umfpack
# But this doesn't stop it from compiling / working without it

S="${WORKDIR}/${ELMER_ROOT}-${PV}/fem"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch ${FILESDIR}/elmer-fem-Makefile-install.patch
	eautoreconf
}

src_compile() {
	cd "${S}"
	local myconf
	export FC="gfortran"
	export F77="gfortran"
	myconf="$myconf --with-blas --with-lapack --with-arpack --with-huti"
	myconf="$myconf --with-eiof --with-matc"
	#TODO parpack support is not picked up from the arpack package
	#TODO --with-hypre --with-umfpack

	use mpi && myconf="$myconf --with-mpi --with-mpi-dir=/usr"
	use debug &&
		myconf="${myconf} --with-debug" ||
		myconf="${myconf} --without-debug"
	econf $myconf || die "econf failed"
	emake || die "emake failed"
}


src_install() {
	emake ELMER_SOLVER_DATADIR="${D}/usr/share/elmersolver"  DESTDIR="${D}" install || die "emake install failed"
}