libsvm-2.84.ebuild

libsvm-2.84.ebuild (text/plain), 1.52 KB, created by Serkan Kaba (RETIRED) on 2007-04-28 19:32:26 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/libsvm/libsvm-2.81.ebuild,v 1.2 2006/08/01 03:41:25 nichoj Exp $

inherit toolchain-funcs python java-pkg-opt-2 java-pkg-2

DESCRIPTION="Library for Support Vector Machines"
HOMEPAGE="http://www.csie.ntu.edu.tw/~cjlin/libsvm/"
SRC_URI="http://www.csie.ntu.edu.tw/~cjlin/libsvm/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="python"

DEPEND="java? ( >=virtual/jdk-1.4 )"
RDEPEND="java? ( >=virtual/jre-1.4 )"

src_compile() {
	emake CXXC="$(tc-getCXX)" CFLAGS="${CXXFLAGS}" || die

	sed -i -e 's@\.\./@/usr/bin/@g' tools/*.py || die

	if use python ; then
		cd python
		python_version || die
		emake CC="$(tc-getCXX)" \
			CFLAGS="${CXXFLAGS} -I/usr/include/python${PYVER} -I.." all || die
		cd -
	fi

	if use java ; then
		cd java
		rm *.jar
		emake JAVAC_FLAGS="$(java-pkg_javac-args)"
		cd -
	fi
}

src_install() {
	dobin svm-train svm-predict svm-scale || die
	dohtml FAQ.html
	dodoc README

	cd tools
	insinto /usr/share/doc/${PF}/tools
	doins easy.py grid.py subset.py
	docinto tools
	dodoc README
	cd -

	if use python ; then
		cd python
		python_version || die
		insinto /usr/lib/python${PYVER}/site-packages
		doins svmc.so svm.py || die
		docinto python
		dodoc README
		cd -
	fi

	if use java ; then
		cd java
		java-pkg_dojar libsvm.jar
		sed -e 's:libsvm.jar:/usr/share/libsvm/lib/libsvm.jar:g' -i test_applet.html
		docinto html
		java-pkg_dohtml test_applet.html
		cd -
	fi
}