quake1-textures-20060722.ebuild

quake1-textures-20060722.ebuild (text/plain), 2.21 KB, created by Paul Bredbury on 2007-04-16 15:34:42 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

DEBASER_PV="1"
DEBASER_FILE="DebaserTextures_v${DEBASER_PV}.zip"
MY_SKINS="SKINSbmodels-48files-4-23-05.zip"
#MY_TEXTURES="qrp-textures-549files-7-22-06.zip"
MY_TEXTURES="qrp-texturesmany-missing-ones.zip"

DESCRIPTION="Collection of graphical improvements for Quake 1"
HOMEPAGE="http://facelift.quakedev.com/
	http://hosted.planetquake.gamespy.com/starbuck/"
SRC_URI="http://facelift.quakedev.com/download/${MY_SKINS}
	http://shub-hub.quaddicted.com/files/textures_replacement/${MY_TEXTURES}
	http://files.quakeonline.net/textures/qrp/${MY_TEXTURES}
	http://qexpo.quakedev.com/uploaded/6/${DEBASER_FILE}"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debaser demo fuhquake tenebrae"

RDEPEND="|| (
		games-fps/darkplaces
		games-fps/joequake
		tenebrae? ( games-fps/tenebrae )
		games-fps/ezquake-bin
		fuhquake? ( games-fps/fuhquake-bin ) )"
DEPEND="app-arch/unzip"

S=${WORKDIR}
dir=${GAMES_DATADIR}/quake1

src_unpack() {
	unpack ${MY_SKINS} ${MY_TEXTURES}

	# Show the "retexturing project" words at the very start of a new game,
	# if available.
	[[ -e quake-QRP.tga ]] && mv -f quake-QRP.tga textures/quake.tga

	# Move the skin textures to join the others
	mv -f *.tga textures

	unpack ${DEBASER_FILE}
	# Move Debaser textures to join the others
	if use debaser ; then
		# Debaser overrides Quake Rexturing Project
		mv -f *.tga textures
	else
		# Use Debaser texture only when it is not already supplied
		local f
		for f in *.tga ; do
			if [[ ! -f "textures/${f}" ]] ; then
				mv "${f}" textures
			fi
		done
	fi
}

src_install() {
	insinto "${dir}"/id1
	doins -r textures || die "doins textures failed"

	if use demo ; then
		keepdir "${dir}/demo"
		# Set up symlink, for the demo levels to include the textures
		dosym "${dir}/id1/textures" "${dir}/demo/textures"
	fi

	# Support specific engines which need their own directory names
	if use tenebrae ; then
		keepdir "${dir}/tenebrae"
		dosym "${dir}/id1/textures" "${dir}/tenebrae/override"
	fi
	if use fuhquake ; then
		keepdir "${dir}/fuhquake"
		dosym "${dir}/id1/textures" "${dir}/fuhquake/textures"
	fi

	dodoc *.txt

	prepgamesdirs
}